basic/eumel coder 1.8.1

Raw file
Back to index

   1
   2
   3
   4
   5
   6
   7
   8
   9
  10
  11
  12
  13
  14
  15
  16
  17
  18
  19
  20
  21
  22
  23
  24
  25
  26
  27
  28
  29
  30
  31
  32
  33
  34
  35
  36
  37
  38
  39
  40
  41
  42
  43
  44
  45
  46
  47
  48
  49
  50
  51
  52
  53
  54
  55
  56
  57
  58
  59
  60
  61
  62
  63
  64
  65
  66
  67
  68
  69
  70
  71
  72
  73
  74
  75
  76
  77
  78
  79
  80
  81
  82
  83
  84
  85
  86
  87
  88
  89
  90
  91
  92
  93
  94
  95
  96
  97
  98
  99
 100
 101
 102
 103
 104
 105
 106
 107
 108
 109
 110
 111
 112
 113
 114
 115
 116
 117
 118
 119
 120
 121
 122
 123
 124
 125
 126
 127
 128
 129
 130
 131
 132
 133
 134
 135
 136
 137
 138
 139
 140
 141
 142
 143
 144
 145
 146
 147
 148
 149
 150
 151
 152
 153
 154
 155
 156
 157
 158
 159
 160
 161
 162
 163
 164
 165
 166
 167
 168
 169
 170
 171
 172
 173
 174
 175
 176
 177
 178
 179
 180
 181
 182
 183
 184
 185
 186
 187
 188
 189
 190
 191
 192
 193
 194
 195
 196
 197
 198
 199
 200
 201
 202
 203
 204
 205
 206
 207
 208
 209
 210
 211
 212
 213
 214
 215
 216
 217
 218
 219
 220
 221
 222
 223
 224
 225
 226
 227
 228
 229
 230
 231
 232
 233
 234
 235
 236
 237
 238
 239
 240
 241
 242
 243
 244
 245
 246
 247
 248
 249
 250
 251
 252
 253
 254
 255
 256
 257
 258
 259
 260
 261
 262
 263
 264
 265
 266
 267
 268
 269
 270
 271
 272
 273
 274
 275
 276
 277
 278
 279
 280
 281
 282
 283
 284
 285
 286
 287
 288
 289
 290
 291
 292
 293
 294
 295
 296
 297
 298
 299
 300
 301
 302
 303
 304
 305
 306
 307
 308
 309
 310
 311
 312
 313
 314
 315
 316
 317
 318
 319
 320
 321
 322
 323
 324
 325
 326
 327
 328
 329
 330
 331
 332
 333
 334
 335
 336
 337
 338
 339
 340
 341
 342
 343
 344
 345
 346
 347
 348
 349
 350
 351
 352
 353
 354
 355
 356
 357
 358
 359
 360
 361
 362
 363
 364
 365
 366
 367
 368
 369
 370
 371
 372
 373
 374
 375
 376
 377
 378
 379
 380
 381
 382
 383
 384
 385
 386
 387
 388
 389
 390
 391
 392
 393
 394
 395
 396
 397
 398
 399
 400
 401
 402
 403
 404
 405
 406
 407
 408
 409
 410
 411
 412
 413
 414
 415
 416
 417
 418
 419
 420
 421
 422
 423
 424
 425
 426
 427
 428
 429
 430
 431
 432
 433
 434
 435
 436
 437
 438
 439
 440
 441
 442
 443
 444
 445
 446
 447
 448
 449
 450
 451
 452
 453
 454
 455
 456
 457
 458
 459
 460
 461
 462
 463
 464
 465
 466
 467
 468
 469
 470
 471
 472
 473
 474
 475
 476
 477
 478
 479
 480
 481
 482
 483
 484
 485
 486
 487
 488
 489
 490
 491
 492
 493
 494
 495
 496
 497
 498
 499
 500
 501
 502
 503
 504
 505
 506
 507
 508
 509
 510
 511
 512
 513
 514
 515
 516
 517
 518
 519
 520
 521
 522
 523
 524
 525
 526
 527
 528
 529
 530
 531
 532
 533
 534
 535
 536
 537
 538
 539
 540
 541
 542
 543
 544
 545
 546
 547
 548
 549
 550
 551
 552
 553
 554
 555
 556
 557
 558
 559
 560
 561
 562
 563
 564
 565
 566
 567
 568
 569
 570
 571
 572
 573
 574
 575
 576
 577
 578
 579
 580
 581
 582
 583
 584
 585
 586
 587
 588
 589
 590
 591
 592
 593
 594
 595
 596
 597
 598
 599
 600
 601
 602
 603
 604
 605
 606
 607
 608
 609
 610
 611
 612
 613
 614
 615
 616
 617
 618
 619
 620
 621
 622
 623
 624
 625
 626
 627
 628
 629
 630
 631
 632
 633
 634
 635
 636
 637
 638
 639
 640
 641
 642
 643
 644
 645
 646
 647
 648
 649
 650
 651
 652
 653
 654
 655
 656
 657
 658
 659
 660
 661
 662
 663
 664
 665
 666
 667
 668
 669
 670
 671
 672
 673
 674
 675
 676
 677
 678
 679
 680
 681
 682
 683
 684
 685
 686
 687
 688
 689
 690
 691
 692
 693
 694
 695
 696
 697
 698
 699
 700
 701
 702
 703
 704
 705
 706
 707
 708
 709
 710
 711
 712
 713
 714
 715
 716
 717
 718
 719
 720
 721
 722
 723
 724
 725
 726
 727
 728
 729
 730
 731
 732
 733
 734
 735
 736
 737
 738
 739
 740
 741
 742
 743
 744
 745
 746
 747
 748
 749
 750
 751
 752
 753
 754
 755
 756
 757
 758
 759
 760
 761
 762
 763
 764
 765
 766
 767
 768
 769
 770
 771
 772
 773
 774
 775
 776
 777
 778
 779
 780
 781
 782
 783
 784
 785
 786
 787
 788
 789
 790
 791
 792
 793
 794
 795
 796
 797
 798
 799
 800
 801
 802
 803
 804
 805
 806
 807
 808
 809
 810
 811
 812
 813
 814
 815
 816
 817
 818
 819
 820
 821
 822
 823
 824
 825
 826
 827
 828
 829
 830
 831
 832
 833
 834
 835
 836
 837
 838
 839
 840
 841
 842
 843
 844
 845
 846
 847
 848
 849
 850
 851
 852
 853
 854
 855
 856
 857
 858
 859
 860
 861
 862
 863
 864
 865
 866
 867
 868
 869
 870
 871
 872
 873
 874
 875
 876
 877
 878
 879
 880
 881
 882
 883
 884
 885
 886
 887
 888
 889
 890
 891
 892
 893
 894
 895
 896
 897
 898
 899
 900
 901
 902
 903
 904
 905
 906
 907
 908
 909
 910
 911
 912
 913
 914
 915
 916
 917
 918
 919
 920
 921
 922
 923
 924
 925
 926
 927
 928
 929
 930
 931
 932
 933
 934
 935
 936
 937
 938
 939
 940
 941
 942
 943
 944
 945
 946
 947
 948
 949
 950
 951
 952
 953
 954
 955
 956
 957
 958
 959
 960
 961
 962
 963
 964
 965
 966
 967
 968
 969
 970
 971
 972
 973
 974
 975
 976
 977
 978
 979
 980
 981
 982
 983
 984
 985
 986
 987
 988
 989
 990
 991
 992
 993
 994
 995
 996
 997
 998
 999
1000
1001
1002
1003
1004
1005
1006
1007
1008
1009
1010
1011
1012
1013
1014
1015
1016
1017
1018
1019
1020
1021
1022
1023
1024
1025
1026
1027
1028
1029
1030
1031
1032
1033
1034
1035
1036
1037
1038
1039
1040
1041
1042
1043
1044
1045
1046
1047
1048
1049
1050
1051
1052
1053
1054
1055
1056
1057
1058
1059
1060
1061
1062
1063
1064
1065
1066
1067
1068
1069
1070
1071
1072
1073
1074
1075
1076
1077
1078
1079
1080
1081
1082
1083
1084
1085
1086
1087
1088
1089
1090
1091
1092
1093
1094
1095
1096
1097
1098
1099
1100
1101
1102
1103
1104
1105
1106
1107
1108
1109
1110
1111
1112
1113
1114
1115
1116
1117
1118
1119
1120
1121
1122
1123
1124
1125
1126
1127
1128
1129
1130
1131
1132
1133
1134
1135
1136
1137
1138
1139
1140
1141
1142
1143
1144
1145
1146
1147
1148
1149
1150
1151
1152
1153
1154
1155
1156
1157
1158
1159
1160
1161
1162
1163
1164
1165
1166
1167
1168
1169
1170
1171
1172
1173
1174
1175
1176
1177
1178
1179
1180
1181
1182
1183
1184
1185
1186
1187
1188
1189
1190
1191
1192
1193
1194
1195
1196
1197
1198
1199
1200
1201
1202
1203
1204
1205
1206
1207
1208
1209
1210
1211
1212
1213
1214
1215
1216
1217
1218
1219
1220
1221
1222
1223
1224
1225
1226
1227
1228
1229
1230
1231
1232
1233
1234
1235
1236
1237
1238
1239
1240
1241
1242
1243
1244
1245
1246
1247
1248
1249
1250
1251
1252
1253
1254
1255
1256
1257
1258
1259
1260
1261
1262
1263
1264
1265
1266
1267
1268
1269
1270
1271
1272
1273
1274
1275
1276
1277
1278
1279
1280
1281
1282
1283
1284
1285
1286
1287
1288
1289
1290
1291
1292
1293
1294
1295
1296
1297
1298
1299
1300
1301
1302
1303
1304
1305
1306
1307
1308
1309
1310
1311
1312
1313
1314
1315
1316
1317
1318
1319
1320
1321
1322
1323
1324
1325
1326
1327
1328
1329
1330
1331
1332
1333
1334
1335
1336
1337
1338
1339
1340
1341
1342
1343
1344
1345
1346
1347
1348
1349
1350
1351
1352
1353
1354
1355
1356
1357
1358
1359
1360
1361
1362
1363
1364
1365
1366
1367
1368
1369
1370
1371
1372
1373
1374
1375
1376
1377
1378
1379
1380
1381
1382
1383
1384
1385
1386
1387
1388
1389
1390
1391
1392
1393
1394
1395
1396
1397
1398
1399
1400
1401
1402
1403
1404
1405
1406
1407
1408
1409
1410
1411
1412
1413
1414
1415
1416
1417
1418
1419
1420
1421
1422
1423
1424
1425
1426
1427
1428
1429
1430
1431
1432
1433
1434
1435
1436
1437
1438
1439
1440
1441
1442
1443
1444
1445
1446
1447
1448
1449
1450
1451
1452
1453
1454
1455
1456
1457
1458
1459
1460
1461
1462
1463
1464
1465
1466
1467
1468
1469
1470
1471
1472
1473
1474
1475
1476
1477
1478
1479
1480
1481
1482
1483
1484
1485
1486
1487
1488
1489
1490
1491
1492
1493
1494
1495
1496
1497
1498
1499
1500
1501
1502
1503
1504
1505
1506
1507
1508
1509
1510
1511
1512
1513
1514
1515
1516
1517
1518
1519
1520
1521
1522
1523
1524
1525
1526
1527
1528
1529
1530
1531
1532
1533
1534
1535
1536
1537
1538
1539
1540
1541
1542
1543
1544
1545
1546
1547
1548
1549
1550
1551
1552
1553
1554
1555
1556
1557
1558
1559
1560
1561
1562
1563
1564
1565
1566
1567
1568
1569
1570
1571
1572
1573
1574
1575
1576
1577
1578
1579
1580
1581
1582
1583
1584
1585
1586
1587
1588
1589
1590
1591
1592
1593
1594
1595
1596
1597
1598
1599
1600
1601
1602
1603
1604
1605
1606
1607
1608
1609
1610
1611
1612
1613
1614
1615
1616
1617
1618
1619
1620
1621
1622
1623
1624
1625
1626
1627
1628
1629
1630
1631
1632
1633
1634
1635
1636
1637
1638
1639
1640
1641
1642
1643
1644
1645
1646
1647
1648
1649
1650
1651
1652
1653
1654
1655
1656
1657
1658
1659
1660
1661
1662
1663
1664
1665
1666
1667
1668
1669
1670
1671
1672
1673
1674
1675
1676
1677
1678
1679
1680
1681
1682
1683
1684
1685
1686
1687
1688
1689
1690
1691
1692
1693
1694
1695
1696
1697
1698
1699
1700
1701
1702
1703
1704
1705
1706
1707
1708
1709
1710
1711
1712
1713
1714
1715
1716
1717
1718
1719
1720
1721
1722
1723
1724
1725
1726
1727
1728
1729
1730
1731
1732
1733
1734
1735
1736
1737
1738
1739
1740
1741
1742
1743
1744
1745
1746
1747
1748
1749
1750
1751
1752
1753
1754
1755
1756
1757
1758
1759
1760
1761
1762
1763
1764
1765
1766
1767
1768
1769
1770
1771
1772
1773
1774
1775
1776
1777
1778
1779
1780
1781
1782
1783
1784
1785
1786
1787
1788
1789
1790
1791
1792
1793
1794
1795
1796
1797
1798
1799
1800
1801
1802
1803
1804
1805
1806
1807
1808
1809
1810
1811
1812
1813
1814
1815
1816
1817
1818
1819
1820
1821
1822
1823
1824
1825
1826
1827
1828
1829
1830
1831
1832
1833
1834
1835
1836
1837
1838
1839
1840
1841
1842
1843
1844
1845
1846
1847
1848
1849
1850
1851
1852
1853
1854
1855
1856
1857
1858
1859
1860
1861
1862
1863
1864
1865
1866
1867
1868
1869
1870
1871
1872
1873
1874
1875
1876
1877
1878
1879
1880
1881
1882
1883
1884
1885
1886
1887
1888
1889
1890
1891
1892
1893
1894
1895
1896
1897
1898
1899
1900
1901
1902
1903
1904
1905
1906
1907
1908
1909
1910
1911
1912
1913
1914
1915
1916
1917
1918
1919
1920
1921
1922
1923
1924
1925
1926
1927
1928
1929
1930
1931
1932
1933
1934
1935
1936
1937
1938
1939
1940
1941
1942
1943
1944
1945
1946
1947
1948
1949
1950
1951
1952
1953
1954
1955
1956
1957
1958
1959
1960
1961
1962
1963
1964
1965
1966
1967
1968
1969
1970
1971
1972
1973
1974
1975
1976
1977
1978
1979
1980
1981
1982
1983
1984
1985
1986
1987
1988
1989
1990
1991
1992
1993
1994
1995
1996
1997
1998
1999
2000
2001
2002
2003
2004
2005
2006
2007
2008
2009
2010
2011
2012
2013
2014
2015
2016
2017
2018
2019
2020
2021
2022
2023
2024
2025
2026
2027
2028
2029
2030
2031
2032
2033
2034
2035
2036
2037
2038
2039
2040
2041
2042
2043
2044
2045
2046
2047
2048
2049
2050
2051
2052
2053
2054
2055
2056
2057
2058
2059
2060
2061
2062
2063
2064
2065
2066
2067
2068
2069
2070
2071
2072
2073
2074
2075
2076
2077
2078
2079
2080
2081
2082
2083
2084
2085
2086
2087
2088
2089
2090
2091
2092
2093
2094
2095
2096
2097
2098
2099
2100
2101
2102
2103
2104
2105
2106
2107
2108
2109
2110
2111
2112
2113
2114
2115
2116
2117
2118
2119
2120
2121
2122
2123
2124
2125
2126
2127
2128
2129
2130
2131
2132
2133
2134
2135
2136
2137
2138
2139
2140
2141
2142
2143
2144
2145
2146
2147
2148
2149
2150
2151
2152
2153
2154
2155
2156
2157
2158
2159
2160
2161
2162
2163
2164
2165
2166
2167
2168
2169
2170
2171
2172
2173
2174
2175
2176
2177
2178
2179
2180
2181
2182
2183
2184
2185
2186
2187
2188
2189
2190
2191
2192
2193
2194
2195
2196
2197
2198
2199
2200
2201
2202
2203
2204
2205
2206
2207
2208
2209
2210
2211
2212
2213
2214
2215
2216
2217
2218
2219
2220
2221
2222
2223
2224
2225
2226
2227
2228
2229
2230
2231
2232
2233
2234
2235
2236
2237
2238
2239
2240
2241
2242
2243
2244
2245
2246
2247
2248
2249
2250
2251
2252
2253
2254
2255
2256
2257
2258
2259
2260
2261
2262
2263
2264
2265
2266
2267
2268
2269
2270
2271
2272
2273
2274
2275
2276
2277
2278
2279
2280
2281
2282
2283
2284
2285
2286
2287
2288
2289
2290
2291
2292
2293
2294
2295
2296
2297
2298
2299
2300
2301
2302
2303
2304
2305
2306
2307
2308
2309
2310
2311
2312
2313
2314
2315
2316
2317
2318
2319
2320
2321
2322
2323
2324
2325
2326
2327
2328
2329
2330
2331
2332
2333
2334
2335
2336
2337
2338
2339
2340
2341
2342
2343
2344
2345
2346
2347
2348
2349
2350
2351
2352
2353
2354
2355
2356
2357
2358
2359
2360
2361
2362
2363
2364
2365
2366
2367
2368
2369
2370
2371
2372
2373
2374
2375
2376
2377
2378
2379
2380
2381
2382
2383
2384
2385
2386
2387
2388
2389
2390
2391
2392
2393
2394
2395
2396
2397
2398
2399
2400
2401
2402
2403
2404
2405
2406
2407
2408
2409
2410
2411
2412
2413
2414
2415
2416
2417
2418
2419
2420
2421
2422
2423
2424
2425
2426
2427
2428
2429
2430
2431
2432
2433
2434
2435
2436
2437
2438
2439
2440
2441
2442
2443
2444
2445
2446
2447
2448
2449
2450
2451
2452
2453
2454
2455
2456
2457
2458
2459
2460
2461
2462
2463
2464
2465
2466
2467
2468
2469
2470
2471
2472
2473
2474
2475
2476
2477
2478
2479
2480
2481
2482
2483
2484
2485
2486
2487
2488
2489
2490
2491
2492
2493
2494
2495
2496
2497
2498
2499
2500
2501
2502
2503
2504
2505
2506
2507
2508
2509
2510
2511
2512
2513
2514
2515
2516
2517
2518
2519
2520
2521
2522
2523
2524
2525
2526
2527
2528
2529
2530
2531
2532
2533
2534
2535
2536
2537
2538
2539
2540
2541
2542
2543
2544
2545
2546
2547
2548
2549
2550
2551
2552
2553
2554
2555
2556
2557
2558
2559
2560
2561
2562
2563
2564
2565
2566
2567
2568
2569
2570
2571
2572
2573
2574
2575
2576
2577
2578
2579
2580
2581
2582
2583
2584
2585
2586
2587
2588
2589
2590
2591
2592
2593
2594
2595
2596
2597
2598
2599
2600
2601
2602
2603
2604
2605
2606
2607
2608
2609
2610
2611
2612
2613
2614
2615
2616
2617
2618
2619
2620
2621
2622
2623
2624
2625
2626
2627
2628
2629
2630
2631
2632
2633
2634
2635
2636
2637
2638
2639
2640
2641
2642
2643
2644
2645
2646
2647
2648
2649
2650
2651
2652
2653
2654
2655
2656
2657
2658
2659
2660
2661
2662
2663
2664
2665
2666
2667
2668
2669
2670
2671
2672
2673
2674
2675
2676
2677
2678
2679
2680
2681
2682
2683
2684
2685
2686
2687
2688
2689
2690
2691
2692
2693
2694
2695
2696
2697
2698
2699
2700
2701
2702
2703
2704
2705
2706
2707
2708
2709
2710
2711
2712
2713
2714
2715
2716
2717
2718
2719
2720
2721
2722
2723
2724
2725
2726
2727
2728
2729
2730
2731
2732
2733
2734
2735
2736
2737
2738
2739
2740
2741
2742
2743
2744
2745
2746
2747
2748
2749
2750
2751
2752
2753
2754
2755
2756
2757
2758
2759
2760
2761
2762
2763
2764
2765
2766
2767
2768
2769
2770
2771
2772
2773
2774
2775
2776
2777
2778
2779
2780
2781
2782
2783
2784
2785
2786
2787
2788
2789
2790
2791
2792
2793
2794
2795
2796
2797
2798
2799
2800
2801
2802
2803
2804
2805
2806
2807
2808
2809
2810
2811
2812
2813
2814
2815
2816
2817
2818
2819
2820
2821
2822
2823
2824
2825
2826
2827
2828
2829
2830
2831
2832
2833
2834
2835
2836
2837
2838
2839
2840
2841
2842
2843
2844
2845
2846
2847
2848
2849
2850
2851
2852
2853
2854
2855
2856
2857
2858
2859
2860
2861
2862
2863
2864
2865
2866
2867
2868
2869
2870
2871
2872
2873
2874
2875
2876
2877
2878
2879
2880
2881
2882
2883
2884
2885
2886
2887
2888
2889
2890
2891
2892
2893
2894
2895
2896
2897
2898
2899
2900
2901
2902
2903
2904
2905
2906
2907
2908
2909
2910
2911
2912
2913
2914
2915
2916
2917
2918
2919
2920
2921
2922
2923
2924
2925
2926
2927
2928
2929
2930
2931
2932
2933
2934
2935
2936
2937
2938
2939
2940
2941
2942
2943
2944
2945
2946
2947
2948
2949
2950
2951
2952
2953
2954
2955
2956
2957
2958
2959
2960
2961
2962
2963
2964
2965
2966
2967
2968
2969
2970
2971
2972
2973
2974
2975
2976
2977
2978
2979
2980
2981
2982
2983
2984
2985
2986
2987
2988
2989
2990
2991
2992
2993
2994
2995
2996
2997
2998
2999
3000
3001
3002
3003
3004
3005
3006
3007
3008
3009
3010
3011
3012
3013
3014
3015
3016
3017
3018
3019
3020
3021
3022
3023
3024
3025
3026
3027
3028
3029
3030
3031
3032
3033
3034
3035
3036
3037
3038
3039
3040
3041
3042
3043
3044
3045
3046
3047
3048
3049
3050
3051
3052
3053
3054
3055
3056
3057
3058
3059
3060
3061
3062
3063
3064
3065
3066
3067
3068
3069
3070
3071
3072
3073
3074
3075
3076
3077
3078
3079
3080
3081
3082
3083
3084
3085
PACKET eumel coder                                 (* Autor: U. Bartling *) 
       DEFINES coder on, coder off,
               declare, define, apply, identify,
               :=, =,
               dump,
 
               LIB,

               LABEL,
               gosub, goret,
               computed branch,
               complement condition code,

               ADDRESS ,
               GLOB, LOC, REF, DEREF,
               ref length,
               +, 
               adjust,
               get base,
               is global, is local, is ref,
 
               DTYPE, 
               type class, type name,
               void type, int type, real type, text type, bool type, 
               bool result type, dataspace type, undefined type, 
               row type, struct type, proc type, end type,
 
               OPN, 
               set length of local storage, 
               begin module, end module, 
               is proc, is eumel 0 instruction,
               address, operation,
               nop, 
               mnemonic, 

               parameter,
               next param,
               NEXTPARAM, 
               access , 
               dtype , 
               param address,
               same type ,
 
               reserve storage, 
               allocate denoter , 
               allocate variable, 
               data allocation by coder ,
               data allocation by user,
 
               run, run again, 
               insert,
               prot, prot off,
               check, check on, check off,

               help, bulletin, packets,

(**************************************************************************)
(*                                                                        *) 
(*                         E U M E L  -  C O D E R                        *) 
(*                                                                        *) 
(*                                                                        *) 
(*   Zur Beschreibung des Coders siehe                                    *) 
(*         U.Bartling, J. Liedtke: EUMEL-Coder-Interface                  *) 
(*                                                                        *) 
(*   Stand der Dokumentation  : 29.10.1986                                *) 
(*   Stand der Implementation : 03.09.1986                                *) 
(*                                                                        *) 
(*                                                                        *) 
(**************************************************************************) 
 
#page#
(**************************************************************************) 
(*                                                                        *) 
(*                  0. Datentyp DINT                          03.09.1987  *) 
(*                                                                        *) 
(*   Definition    des Datentyps                                          *) 
(*                 arithmetischer Operationen                             *) 
(*            und  Konvertierungsprozeduren                               *) 
(*                                                                        *) 
(**************************************************************************) 


               DINT,
               -, *, DIV, MOD, <, <=,
               AND, OR, XOR,
               dput, dget, dmov,
               ddec1, dinc1, dinc, ddec,
               dadd, dsub,
               dequ, dlseq,
               INCR, DECR,
               put, get, cout,
               text, real, int, dint,
               replace, DSUB :
 
 
TYPE DINT = STRUCT (INT low, high) ; 


REAL VAR   real value ;           (* auch fuer Ausrichtung ! *)
TEXT VAR convertion buffer ;

DINT CONST dint0 :: dint(0) ;
DINT VAR result  :: dint 0 ;
  
 
DINT PROC dint (INT CONST number) : 
    EXTERNAL 144
ENDPROC dint ; 

INT PROC int (DINT CONST i) : 
    EXTERNAL 143
ENDPROC int;

REAL PROC real (DINT CONST number) : 
    real value := 65536.0 * real (number.high) ; 

    IF   number.low >= 0 
    THEN real value INCR real (number.low) 
    ELSE real value INCR (real (number.low AND maxint) + 32768.0) 
    FI ; 
    real value
ENDPROC real ; 

DINT PROC dint (REAL CONST number) : 
    real value := abs (number) ;
    REAL CONST low := real value MOD 65536.0 ; 
   
    result.high := int(real value / 65536.0) ; 
    IF   low < 32768.0 
    THEN result.low := int (low)
    ELSE result.low := int (low-32768.0) OR minint
    FI ;
    IF number < 0.0 THEN dsub (dint0, result, result) FI ;
    result
ENDPROC dint ; 

TEXT PROC text (DINT CONST number) :
    IF number.high = 0 THEN convert low part only
                       ELSE convert number 
    FI ; 
    convertion buffer .
 
convert low part only : 
    IF number.low >= 0 THEN convertion buffer := text (number.low) 
                       ELSE convertion buffer := text (real of low) ;
                            erase decimal point
    FI . 

real of low : 
    real (number.low AND maxint) + 32768.0 .

convert number : 
    convertion buffer := text (real(number)) ;
    erase decimal point .

erase decimal point :
    convertion buffer := subtext (convertion buffer, 1, LENGTH convertion buffer-2)
ENDPROC text;

DINT PROC dint (TEXT CONST dint txt) :
    convertion buffer := dint txt ;
    INT CONST dot pos :: pos (convertion buffer, ".") ; 
    IF dot pos = 0 THEN convertion buffer CAT ".0" FI ;
    dint (real(convertion buffer))
ENDPROC dint ;

PROC get (DINT VAR dest) : 
    REAL VAR number ;
    get (number) ;
    dest := dint (number)
ENDPROC get ; 

PROC put (DINT CONST number) : 
    put (text (number));
ENDPROC put ; 

PROC cout (DINT CONST number) : 
    EXTERNAL 61
ENDPROC cout;

OP := (DINT VAR a, DINT CONST b) : 
#   INLINE ;   #
    dmov (b, a); 
ENDOP :=;

OP INCR (DINT VAR a, DINT CONST b) : 
#   INLINE ;   #
    dinc (b, a); 
ENDOP INCR;
 
OP DECR (DINT VAR a, DINT CONST b) : 
#   INLINE ;   #
    ddec (b, a); 
ENDOP DECR;

BOOL OP = (DINT CONST a, b) : 
    EXTERNAL 137 
ENDOP =;

BOOL OP <= (DINT CONST a, b) : 
    EXTERNAL 138 
ENDOP <=;

BOOL OP < (DINT CONST a, b) :
#   INLINE ;   #
    NOT (b <= a)
ENDOP <;

BOOL PROC dequ (DINT CONST a, b) : 
    EXTERNAL 137 
ENDPROC dequ ;

BOOL PROC dlseq (DINT CONST a, b) : 
    EXTERNAL 138 
ENDPROC dlseq ;

PROC replace (TEXT VAR text, INT CONST index of dint, DINT CONST value) :
    INT VAR subscript := index of dint * 2 ;
    replace (text, subscript - 1,value.low); 
    replace (text, subscript, value.high); 
ENDPROC replace;

DINT OP DSUB (TEXT CONST text, INT CONST index of dint) : 
    INT  VAR subscript := index of dint * 2 ;
    result.low  := text ISUB subscript - 1; 
    result.high := text ISUB subscript;
    result
ENDOP DSUB;

DINT OP + (DINT CONST a, b) :
    EXTERNAL 135 
ENDOP + ;
 
DINT OP - (DINT CONST a, b) :
    EXTERNAL 136 
ENDOP - ;

PROC dadd (DINT CONST a, b, DINT VAR res) :
    EXTERNAL 135 
ENDPROC dadd ;
 
PROC dsub (DINT CONST a, b, DINT VAR res) :
    EXTERNAL 136
ENDPROC dsub ;

PROC dinc (DINT CONST source, DINT VAR dest) : 
    EXTERNAL 133 
ENDPROC dinc ; 
 
PROC ddec (DINT CONST source, DINT VAR dest) : 
    EXTERNAL 134 
ENDPROC ddec ; 
 
PROC dmov (DINT CONST source, DINT VAR dest) : 
    EXTERNAL 130 
ENDPROC dmov; 

DINT OP DIV (DINT CONST a,b) :
    EXTERNAL 152
ENDOP DIV ;

DINT OP MOD (DINT CONST a,b) :
    EXTERNAL 153
ENDOP MOD ;

DINT OP AND (DINT CONST a,b) :
    result.low  := a.low  AND b.low ;
    result.high := a.high AND b.high ;
    result
ENDOP AND ;

DINT OP OR (DINT CONST a,b) :
    result.low  := a.low  OR b.low ;
    result.high := a.high OR b.high ;
    result
ENDOP OR ;

DINT OP XOR (DINT CONST a,b) :
    result.low  := a.low  XOR b.low ;
    result.high := a.high XOR b.high ;
    result
ENDOP XOR ;

PROC dput (ROW 32000 DINT VAR array, DINT CONST index, value) : 
    EXTERNAL 139 
ENDPROC dput ; 
 
PROC dget (ROW 32000 DINT VAR array, DINT CONST index, DINT VAR dest) : 
    EXTERNAL 140 
ENDPROC dget ; 

PROC dinc1 (DINT VAR dest) : 
    EXTERNAL 131 
ENDPROC dinc1 ; 
 
PROC ddec1 (DINT VAR dest) :
    EXTERNAL 132 
ENDPROC ddec1 ; 

DINT OP * (DINT CONST a,b) :
    EXTERNAL 151
ENDOP * ; 

#page#
                   (***** Globale Variable *****) 

TEXT VAR object name;
 
FILE VAR bulletin file; 
 
INT VAR memory management mode, global address offset, packet base,
        hash table pointer, nt link, permanent pointer, param link,
        packet link, index, mode, field pointer, word,
        number of errors := 0 ;
 
BOOL VAR found, end of params;
 
#page#
(**************************************************************************) 
(*                                                                        *) 
(*                  1. Interface zum ELAN-Compiler            13.11.1986  *) 
(*                              1.8.1                                     *) 
(*                                                                        *) 
(*   Beschreibung der      Tabellen (-groessen),                          *) 
(*                         internen Vercodung von Typen                   *) 
(*                    und  Kennungen .                                    *) 
(*   Initialisieren und Beenden des Compilers,                            *) 
(*   Lesen aus und Schreiben in Namens- bzw. Permanent-Tabelle            *) 
(*                                                                        *) 
(**************************************************************************) 
 

TYPE LIB = STRUCT (TEXT name, INT nt link, pt link, ADDRESS base) ;

LET  begin of hash table         =     0 ,
     end of hash table           =  1023 ,
 
     begin of permanent table    = 22784 ,
       before first pt entry     = 22784 ,
       first permanent entry     = 22785 ,
     end of permanent table      = 32767 , 

     wordlength                  =     1 ,  (* compile  u n d  run time *)
     two word length             =     2 ,
     three word length           =     3 ,
     four word length            =     4 ,
 
     permanent param const             = 10000 ,
     permanent param var               = 20000 ,
     permanent proc op                 = 30000 ,
     permanent type                    = 30000 ,
     permanent row                     =    10 ,
     permanent struct                  =    11 ,
     permanent param proc              =    12 ,
     permanent param proc end marker   =     0 ,
     permanent type field              =     0 ,

     ptt limit                         = 10000 ,
     begin of pt minus ptt limit       = 12784 ,
     begin of pt minus ptt limit 1     = 12785 , (* plus wordlength *)
 
     void id                           =     0 ,
     int id                            =     1 ,
     real id                           =     2 ,
     string id                         =     3 ,
     bool id                           =     5 ,
     bool result id                    =     6 ,
     dataspace id                      =     7 ,
     undefined id                      =     9 ,
     row id                            =    10 ,
     struct id                         =    11 ,
     end id                            =     0 ,

     const                             =     1 , 
     var                               =     2 ,
     proc id                           =     3 ,
(*   denoter                           =     5 , *)
     bold                              =     2 ,
 
     ins                               = TRUE ,
     no ins                            = FALSE ,
     no lst                            = FALSE ,
     sermon                            = TRUE  ,
     no sermon                         = FALSE ,
 
     run again mode                    =     0 ,
     compile file mode                 =     1 ,
     prep coder mode                   =     5 , 

     warning message                   =     2 , 
     error message                     =     4 ,
 
     point line                        = "..............." ;
 
INT CONST permanent packet            :=     -2 ,
          permanent end               :=     -3 ;

BOOL VAR coder active                 := FALSE ; 

INT  VAR run again mod nr             :=     0 ;
 
 
                     (***** Start/Ende *****)
 
LET coder not active      = "CODER not active" ,
    illegal define packet = "illegal define packet" ;

PROC coder on (INT CONST data allocation mode) : 
    mark coder on ; 
    init opn section ; 
    init compiler ;
    init memory management .
 
mark coder on :
    coder active := TRUE .

init memory management :
    memory management mode := data allocation mode .
 
init compiler :
    no do again ;
    elan (prep coder mode, bulletin file, "", run again mod nr,
          no ins, no lst, check option, no sermon)

ENDPROC coder on;
 
PROC coder off (BOOL CONST insert, sermon, OPN CONST start proc) :
    IF coder active 
       THEN mark coder off ; 
            end coder (insert, sermon, start mod nr if no insert)
       ELSE errorstop (coder not active)
    FI .
 
start mod nr if no insert :
    IF insert THEN run again mod nr := 0
              ELSE run again mod nr := start proc.mod nr
    FI ;
    run again mod nr .

mark coder off :
    reset memory management mode ;
    init opn section ;
    coder active := FALSE
ENDPROC coder off ; 
 
PROC end coder (BOOL CONST insert wanted, sermon wanted, INT CONST mod) :
    EXTERNAL 10021
ENDPROC end coder ; 

PROC elan (INT CONST mode, FILE VAR source, TEXT CONST line, 
           INT VAR start module number, BOOL CONST ins, lst, rtc, ser) :
  EXTERNAL 256
ENDPROC elan ;

PROC unsigned arithmetic : 
    EXTERNAL 92 
ENDPROC unsigned arithmetic ;
 

                   (*****    Paket-Rahmen    *****)

PROC declare (TEXT CONST name, LIB VAR packet) :
    packet.name := name
ENDPROC declare ;

PROC define (LIB VAR packet) :
    check if definition possible ;
    declare object (packet.name, packet.nt link, packet.pt link) ;
    open packet (packet.nt link, global address offset, packet base) ;
    set to actual base (packet) .

check if definition possible :
    IF NOT coder active THEN errorstop (coder not active) FI ;
    IF module open      THEN errorstop (illegal define packet) FI
ENDPROC define ;

PROC open packet (INT CONST nt link of packet name, INT VAR offset, base) :
    EXTERNAL 10032 
ENDPROC open packet ;

PROC identify (TEXT CONST name, LIB VAR packet, BOOL VAR packet exists) :
     to packet (name) ;
     packet exists := found ;
     IF found THEN packet.name    := name ;
                   packet.nt link := nt link ;
                   packet.pt link := packet link ;
                   get pbas (packet.base)
     FI
ENDPROC identify ;

 
                   (***** Hash/Namenstabelle *****) 
.
next hash entry :
     hash table pointer INCR wordlength .

end of hash table reached :
     hash table pointer > end of hash table .

yet another nt entry :
     nt link := cdb int (nt link) ;
     nt link <> 0 . ;
 
PROC declare object (TEXT CONST name, INT VAR nt link, pt pointer) : 
    EXTERNAL 10031
ENDPROC declare object ; 
 
PROC to object (TEXT CONST searched object) : 
     hash ;
     search nt entry .

hash :
     hash code := 0 ;
     FOR index FROM 1 UPTO LENGTH searched object REP
         addmult cyclic
     ENDREP .

addmult cyclic :
     hash code INCR hash code ;
     IF hash code > end of hash table THEN wrap around FI ;
     hash code := (hash code + code (searched object SUB index)) MOD 1024 .

wrap around :
     hash code DECR end of hash table .

hash code : nt link .

search nt entry :
     found := FALSE ;
     WHILE yet another nt entry REP
          read current entry ;
          IF object name = searched object 
             THEN found := TRUE ;
                  LEAVE to object
          FI
     PER .

read current entry :
     permanent pointer := cdb int (nt link + wordlength) ;
     object name := cdb text (nt link + two word length)
ENDPROC to object ;


                 (***** Permanent Tabelle *****) 
.
next procedure :
     permanent pointer := cdb int (permanent pointer) . ;

PROC next pt param :
     mode := cdb int (param link) MOD ptt limit ;
     param link INCR wordlength ;
     IF   mode = permanent row    THEN skip over permanent row 
     ELIF mode = permanent struct THEN skip over permanent struct
     FI ;
     set end marker if end of list .

skip over permanent row :
     param link INCR wordlength ;
     next pt param .

skip over permanent struct :
     REP
         mode := cdb int (param link) ;
         IF mode = permanent type field
            THEN param link INCR wordlength ;
                 LEAVE skip over permanent struct
         FI ;
         next pt param
     PER
ENDPROC next pt param ;

PROC set end marker if end of list :
     mode := cdb int (param link) ;
     end of params := mode >= permanent proc op OR mode <= 0 
ENDPROC set end marker if end of list ;

PROC get type and mode (INT VAR type) : 
     mode := cdb int (param link) ;
     IF   mode < 0                    THEN type := 2769 + (32767 + mode) ;
                                           mode := 0
     ELIF mode = permanent param proc THEN translate type
                                      ELSE type := mode MOD ptt limit ;
                                           mode DECR type ;
                                           translate type if necessary ;
                                           translate mode if necessary 
     FI .

translate type if necessary :
     IF permanent row or struct THEN translate type FI .

translate type :
     type := param link - begin of pt minus ptt limit .

translate mode if necessary : 
    IF   mode = permanent param const THEN mode := const
    ELIF mode = permanent param var   THEN mode := var
    FI .

permanent row or struct :
     type = permanent row OR type = permanent struct
ENDPROC get type and mode ;

PROC put next permanent (INT CONST permanent value) : 
    EXTERNAL 10020
ENDPROC put next permanent ; 
 

                 (***** Allgemeine Zugriffsprozeduren *****) 

INT PROC cdb int (INT CONST index) :
   EXTERNAL 116
ENDPROC cdb int ;

TEXT PROC cdb text (INT CONST index) :
   EXTERNAL 117
ENDPROC cdb text ;
 

#page#
(**************************************************************************) 
(*                                                                        *) 
(*                  2. Spruenge und Marken                    07.10.1986  *) 
(*                                                                        *) 
(*   Definition des Datentyps LABEL                                       *) 
(*                                                                        *) 
(*   Deklaration, Definition und Applikation von Marken                   *) 
(*                                                                        *) 
(**************************************************************************) 



TYPE LABEL = INT ; 

BOOL VAR invers :: FALSE ; 
 
PROC declare (LABEL VAR label) : 
    CONCR (label) := 0
ENDPROC declare ; 
 
PROC define (LABEL VAR label) : 
    EXTERNAL 10085
ENDPROC define ; 
 
PROC complement condition code : 
    invers := NOT invers
ENDPROC complement condition code ; 
 
PROC apply (LABEL VAR label) : 
    EXTERNAL 10151
ENDPROC apply ; 
 
PROC apply (LABEL VAR label, BOOL CONST condition) : 
    IF condition xor invers THEN branch true (label) 
                            ELSE branch false (label)
    FI ;
    invers := FALSE .

condition xor invers : 
    IF condition THEN NOT invers
                 ELSE invers
    FI
ENDPROC apply ; 
 
OP := (LABEL VAR global label, local label) : (* EQUATE ! *)
    EXTERNAL 10014 
ENDOP := ; 
 
TEXT PROC dump (LABEL CONST label) : 
    "LAB " + text (CONCR (label)) 
ENDPROC dump ; 
 
PROC gosub (LABEL VAR label) : 
    EXTERNAL 10015 
ENDPROC gosub ; 
 
PROC goret : 
    s0 (q goret code) 
ENDPROC goret ; 
 
PROC branch true (LABEL VAR label) : 
    EXTERNAL 10028
ENDPROC branch true ; 
 
PROC branch false (LABEL VAR label) : 
    EXTERNAL 10029
ENDPROC branch false ; 

PROC computed branch (ADDRESS CONST switch, INT CONST limit, LABEL VAR out) :
    s1 (q esc case, REPR switch) ;
    s0 (limit) ; 
    branch false (out)
ENDPROC computed branch ;
 
 
#page#
(**************************************************************************) 
(*                                                                        *) 
(*                  3. Datenaddressen                         13.11.1986  *) 
(*                                                                        *) 
(*   Definition des Datentyps ADDRESS                                     *) 
(*                                                                        *) 
(*   Aufbau von Datenaddressen (Vercodung)                                *) 
(*   Fortschalten und Ausrichten von Adressen                             *) 
(*   Behandlung von Paketbasis-Adressen                                   *) 
(*   Bereitstellen der Fehlermeldung "address overflow" (Coder-intern)    *) 
(*                                                                        *) 
(**************************************************************************) 
 
 
 
TYPE ADDRESS = STRUCT (INT kind, value) ; 
 
LET global                 = 0 , 
    local                  = 1 , 
    ref mask               = 2 , 
    global ref             = 2 , 
    local ref              = 3 , 
    module nr              = 4 ,
    immediate value        = 5 ,
    p base                 = 6 ,
 
    eumel0 stack offset    = 4 ,
    local address limit    = 16 384 ,
    global address zero    = 0 ,
 
    illegal ref operation  = "REF not allowed" , 
    deref on non ref       = "DEREF on non-ref address" ,
    global ref not allowed = "GLOBAL REF not allowed" , 
    unknown kind           = "Unknown address kind" , 
    address overflow       = "Address Overflow" , 
    illegal plus operation = "+ not allowed" ;
 
ADDRESS VAR result addr;
 
INT CONST ref length :: 2 ;

OP := (ADDRESS VAR l, ADDRESS CONST r) : 
    CONCR (l) := CONCR (r) 
ENDOP := ; 
 
ADDRESS OP GLOB (INT CONST address level) : 
    result addr.kind  := global ; 
    result addr.value := address level ; 
    IF memory management mode = data allocation by user
       THEN result addr.value INCR global address offset
    FI ;
    result addr
ENDOP GLOB ;

ADDRESS OP LOC (INT CONST address level) : 
    result addr.kind  := local ;
    result addr.value := address level + eumel0 stack offset ; 
    result addr
ENDOP LOC ; 
 
ADDRESS OP REF (ADDRESS CONST addr) : 
    CONCR (result addr) := CONCR (addr) ;
    IF   result addr.kind = local  THEN result addr.kind INCR ref mask
    ELIF result addr.kind = global THEN errorstop (global ref not allowed)
                                   ELSE errorstop (illegal ref operation)
    FI ;
    result addr 
ENDOP REF ; 
 
ADDRESS OP DEREF (ADDRESS CONST ref address) : 
    CONCR (result addr) := CONCR (ref address) ;
    IF is not local ref THEN errorstop (deref on non ref) FI ; 
    result addr.kind DECR ref mask ; 
    result addr .
 
is not local ref :
    result addr.kind <> local ref
ENDOP DEREF ;
 
INT OP REPR (ADDRESS CONST addr) : 
    CONCR (result addr) := CONCR (addr) ;
    SELECT result addr.kind OF 
        CASE global     :
        CASE local      : set bit (result addr.value, 15) 
        CASE global ref : errorstop (global ref not allowed)
        CASE local ref  : prep local ref 
        OTHERWISE errorstop (unknown kind)
    ENDSELECT ; 
    result addr.value .
 
prep local ref : 
    IF address limit exceeded THEN errorstop (address overflow) FI ;
    set bit (result addr.value, 14) ; 
    set bit (result addr.value, 15) .

address limit exceeded :
    result addr.value < eumel0 stack offset OR
    result addr.value > local address limit
ENDOP REPR ; 
 
PROC get base (LIB CONST packet, ADDRESS VAR base) :
    CONCR (base) := CONCR (packet.base)
ENDPROC get base ;

PROC set to actual base (LIB VAR packet) :
    packet.base.kind  := p base ;
    packet.base.value := packet base
ENDPROC set to actual base ;

PROC get pbas (ADDRESS VAR base) :
    base.kind  := p base ;
    base.value := cdbint (packet link + 2)
ENDPROC get pbas ;

BOOL OP = (ADDRESS CONST l,r) :
    l.kind = r.kind AND l.value = r.value
ENDOP = ;

BOOL PROC is ref (ADDRESS CONST addr) : 
    addr.kind = local ref
ENDPROC is ref ; 
 
BOOL PROC is global (ADDRESS CONST addr) : 
    addr.kind = global 
ENDPROC is global ; 
 
BOOL PROC is local (ADDRESS CONST addr) : 
    addr.kind = local 
ENDPROC is local ; 
 
ADDRESS OP + (ADDRESS CONST addr, INT CONST offset) : 
    CONCR (result addr) := CONCR (addr) ; 
    SELECT result addr.kind OF 
        CASE global : inc global
        CASE local  : inc local
        OTHERWISE     errorstop (illegal plus operation) 
    ENDSELECT ; 
    result addr .

inc global : 
    result addr.value INCR offset ; 
    IF result addr.value < 0 THEN errorstop (address overflow) FI .
 
inc local : 
    result addr.value INCR offset ; 
    IF result addr.value < eumel 0 stack offset OR
       result addr.value > local address limit
       THEN errorstop (address overflow)
    FI
ENDOP + ; 
 
PROC adjust (ADDRESS VAR addr, INT CONST adjust length) :
    IF is local or global THEN adjust to length FI . 
 
is local or global :
    addr.kind <= local .

adjust to length :
    mode := addr.value MOD adjust length ;
    IF mode <> 0 THEN addr.value INCR (adjust length-mode) FI
ENDPROC adjust ;

TEXT PROC dump (ADDRESS CONST addr) : 
    kind + text (addr.value) . 
 
kind : 
    SELECT addr.kind OF 
        CASE global          : "GLOBAL " 
        CASE local           : "LOCAL " 
        CASE immediate value : "IMMEDIATE "
        CASE module nr       : "PARAM PROC "
        CASE global ref      : "GLOBAL REF " 
        CASE local ref       : "LOCAL REF " 
        CASE p base          : "PBAS "
        OTHERWISE              "undef. Addr: " 
    ENDSELECT 
ENDPROC dump; 


#page#
(**************************************************************************) 
(*                                                                        *) 
(*                  4. Datentypen   Teil I                    08.09.1986  *) 
(*                                                                        *) 
(*   Definition des Datentyps DTYPE                                       *) 
(*                                                                        *) 
(*   Interne Repraesentation der primitiven Datentypen                    *) 
(*   Identifikation von DTYPEs                                            *)
(*                                                                        *) 
(**************************************************************************) 



TYPE DTYPE = INT ; 
 
OP := (DTYPE VAR l, DTYPE CONST r) : 
    CONCR (l) := CONCR (r) 
ENDOP := ; 
 
BOOL OP = (DTYPE CONST l, r) : 
    CONCR (l) = CONCR (r)
ENDOP = ; 
 
DTYPE PROC void type :      DTYPE :(void id)   ENDPROC  void type ; 
 
DTYPE PROC int  type :      DTYPE :(int id)    ENDPROC  int type ; 
 
DTYPE PROC real type :      DTYPE :(real id)   ENDPROC  real type ; 
 
DTYPE PROC text type :      DTYPE :(string id) ENDPROC  text type ; 
 
DTYPE PROC bool type :      DTYPE :(bool id)   ENDPROC  bool type ; 
 
DTYPE PROC bool result type : DTYPE :(bool result id) ENDPROC  bool result type; 
 
DTYPE PROC dataspace type : DTYPE :(dataspace id) ENDPROC dataspace type ; 
 
DTYPE PROC undefined type : DTYPE :(undefined id) ENDPROC undefined type ; 
 
DTYPE PROC row type  :      DTYPE :(row id)    ENDPROC row type ; 
 
DTYPE PROC struct type :    DTYPE :(struct id) ENDPROC struct type ; 
 
DTYPE PROC proc type :   DTYPE :(permanent param proc) ENDPROC proc type ; 
 
DTYPE PROC end type  :      DTYPE :(end id)    ENDPROC end type ; 
 
INT PROC type class (DTYPE CONST type) : 
    SELECT type id OF 
        CASE int id, real id, bool id, bool result id, string id,
             dataspace id, undefined id : 1 
        CASE void id   : 0 
        CASE row id    : 3 
        CASE struct id : 4 
        CASE permanent param  proc : 5 
        OTHERWISE     pt type 
    ENDSELECT . 

pt type :
    IF type id > ptt limit THEN permanent row or struct
                           ELSE abstract type
    FI .

abstract type : 2 .

permanent row or struct :
    unsigned arithmetic ;
    mode := cdbint (type link into pt) MOD ptt limit ; 
    IF   mode = struct id            THEN 4
    ELIF mode = row id               THEN 3
    ELIF mode = permanent param proc THEN 5
                                     ELSE 2
    FI .
 
type link into pt :
    type id + begin of pt minus ptt limit .

type id : CONCR (type)
ENDPROC type class ; 
 
PROC identify (TEXT CONST name,INT VAR size, align, DTYPE VAR type) : 
    SELECT type pos OF 
          CASE 1   : size := 0; align := 0; type id := void id
          CASE 6   : size := 1; align := 1; type id := int id
          CASE 10  : size := 4; align := 4; type id := real id
          CASE 15  : size := 8; align := 4; type id := string id
          CASE 20  : size := 1; align := 1; type id := bool id
          CASE 25  : size := 1; align := 1; type id := dataspace id
          OTHERWISE  search for type in permanent table 
    ENDSELECT . 
 
type pos : 
    enclose in delimiters ;
    pos (".VOID.INT.REAL.TEXT.BOOL.DATASPACE.", object name) . 
 
enclose in delimiters :
    object name := "." ;
    object name CAT name ;
    object name CAT "." .

search for type in permanent table : 
    to object (name) ;
    IF not found THEN size := 0; align := 0; type id := undefined id
                 ELSE size := cdbint (permanent pointer + two wordlength) ;
                      type id := permanent pointer - begin of permanent table ;
                      IF   size < two wordlength  THEN align := 1
                      ELIF size < four wordlength THEN align := 2
                                                  ELSE align := 4
                      FI
    FI . 
 
not found :
    NOT found OR invalid entry .

invalid entry :
    permanent pointer = 0 OR
    cdb int (permanent pointer + wordlength) <> permanent type .

type id : CONCR (type)
ENDPROC identify ; 
 
 
#page#
(**************************************************************************) 
(*                                                                        *) 
(*                  5. Operationen  Teil I                    30.09.1986  *) 
(*                                                                        *) 
(*   Definition des Datentyps OPN                                         *) 
(*   Primitive Operationen (:=  etc.)                                     *) 
(*   Initialisieren mit den externen Namen der EUMEL-0-Codes              *) 
(*   Bereitstellen dee Fehlermeldung 'proc op expected' (coder-intern)    *) 
(*                                                                        *) 
(**************************************************************************) 


TYPE OPN = STRUCT (INT kind, mod nr, top of stack) ;
 
LET proc op    = 0 ,
    param proc = 1 ,
    eumel 0    = 2 , 
    nil        = 3 , 
 
    param proc at non ref = "PARAM PROC at non-ref address" ,
    proc op expected      = "PROC expected" ;
 
OPN VAR eumel0 opn;
eumel0 opn.kind := eumel0 ;
eumel0 opn.top of stack := 0 ;

eumel0 opn.mod nr := q pp ;
OPN CONST pp       :: eumel0 opn ,
          nop code :: OPN :(nil, 0, 0) ;

IF NOT exists ("eumel0 codes")
    THEN IF yes ("Archive 'eumel coder' eingelegt")
             THEN archive ("eumel coder") ;
                  fetch ("eumel0 codes", archive) ;
                  release (archive)
             ELSE errorstop ("""eumel0 codes"" gibt es nicht")
         FI
FI ;
BOUND THESAURUS VAR initial opcodes :: old ("eumel0 codes") ;
THESAURUS VAR eumel 0 opcodes :: initial opcodes ; 
forget ("eumel0 codes") ;
 
ADDRESS PROC address (OPN CONST opn) :
    IF opn.kind <> proc op THEN errorstop (proc op expected) FI ;
    result addr.kind  := module nr ; 
    result addr.value := opn.mod nr ;
    result addr
ENDPROC address ;
 
OPN PROC operation (ADDRESS CONST addr) : 
    IF addr.kind <> local ref THEN errorstop (param proc at non ref) FI ; 
    OPN VAR opn ;
    opn.kind := param proc ; 
    opn.mod nr :=addr.value ; 
    opn.top of stack := 0 ; 
    opn 
ENDPROC operation ; 
 
TEXT PROC mnemonic (OPN CONST op code) : 
    name (eumel 0 opcodes, op code.mod nr)
ENDPROC mnemonic ;
 
OPN PROC nop : 
    nop code
ENDPROC nop ; 
 
OP := (OPN VAR r, OPN CONST l) : 
    CONCR (r) := CONCR (l) 
ENDOP := ; 
 
BOOL PROC is proc (OPN CONST operation) : 
    operation.kind = proc op
ENDPROC is proc ; 
 
BOOL PROC is eumel 0 instruction (TEXT CONST op code name) : 
    link (eumel 0 opcodes, op code name) <> 0
ENDPROC is eumel 0 instruction ; 

BOOL PROC is eumel 0 instruction (OPN CONST operation) : 
    operation.kind = eumel0
ENDPROC is eumel 0 instruction ; 
 

#page#
(**************************************************************************) 
(*                                                                        *) 
(*                  6. Parameterfeld                          10.04.1986  *) 
(*                                                                        *) 
(*   Bereitstellen des Parameterfeldes                                    *) 
(*   Schreiben und Lesen von Eintraegen im Parameterfeld                  *) 
(*   Fortschalten von Zeigern in das Parameterfeld                        *) 
(*   Bereitstellen der Konstanten 'size of param field' (Coder-intern)    *) 
(*                                                                        *) 
(**************************************************************************) 



LET PARAMDESCRIPTOR = STRUCT (DTYPE type,   INT access, 
                              ADDRESS addr, OPN push opn) , 
 
    size of param field   = 100 ,
    param field exceeded  = "Param Field Overflow",
    param nr out of range = "Illegal Param Number" ;
 
ROW size of param field PARAMDESCRIPTOR VAR param field ;
 
 
                      (***** Schreiben *****) 
 
PROC test param pos (INT CONST param nr) : 
    IF param nr < 1 OR param nr > size of param field
       THEN errorstop (param nr out of range)
    FI 
ENDPROC test param pos ; 
 
PROC declare (INT CONST param nr, DTYPE CONST type) : 
    test param pos (param nr) ; 
    enter type . 
 
enter type :
    CONCR (param field [param nr].type) := CONCR (type) 
ENDPROC declare ; 
 
PROC declare (INT CONST param nr, access) : 
    test param pos (param nr) ; 
    enter access . 

enter access :
    param field [param nr].access := access 
ENDPROC declare ; 
 
PROC define (INT CONST param nr, ADDRESS CONST addr) : 
    test param pos (param nr) ; 
    enter address . 

enter address :
    CONCR (param field [param nr].addr) := CONCR (addr) 
ENDPROC define ; 
 
PROC define (INT CONST param nr, value) : 
    result addr.kind  := immediate value ;
    result addr.value := value ;
    define (param nr, result addr) 
ENDPROC define ; 
 
PROC apply (INT CONST param nr, OPN CONST opn) : 
    test param pos (param nr) ; 
    enter push opn . 
 
enter push opn : 
    CONCR (param field [param nr].push opn) := CONCR (opn) 
ENDPROC apply ; 
 
PROC parameter (INT CONST param nr, DTYPE CONST type, 
                INT CONST access, ADDRESS CONST addr) : 
    test param pos (param nr) ; 
    enter type ; 
    enter access ; 
    enter address ; 
    enter pp as default . 
 
enter type : 
    CONCR (param field [param nr].type) := CONCR (type) .

enter access :
    param field [param nr].access := access .

enter address :
    CONCR (param field [param nr].addr) := CONCR (addr) .

enter pp as default :
    CONCR (param field [param nr].push opn) := CONCR (pp) 
ENDPROC parameter ; 
 
 
                       (***** Lesen *****) 
 
ADDRESS PROC param address (INT CONST param nr) : 
    test param pos (param nr) ; 
    param field [param nr].addr 
ENDPROC param address ; 
 
DTYPE PROC dtype (INT CONST param nr) : 
    test param pos (param nr) ; 
    param field [param nr].type 
ENDPROC dtype ; 
 
INT PROC access (INT CONST param nr) : 
    test param pos (param nr) ; 
    param field [param nr].access 
ENDPROC access ; 
 
 
                      (***** Fortschalten *****) 
 
OP NEXTPARAM (INT VAR param nr) : 
   test param pos (param nr) ; 
   INT CONST class :: type class (param field [param nr].type) ;
   param nr INCR 1 ;
   SELECT class OF
       CASE 3    : NEXTPARAM param nr
       CASE 4,5  : read until end 
    ENDSELECT .

read until end : 
    WHILE NOT end marker read or end of field REP
        NEXTPARAM param nr 
    PER ;
    param nr INCR 1 .
 
end marker read or end of field :
    param nr > size of param field OR
    CONCR (param field [param nr].type) = end id
ENDOP NEXTPARAM ; 
 
INT PROC next param (INT CONST p) : 
    INT VAR index := p ; 
    NEXTPARAM index ; 
    index
ENDPROC next param ; 
 
TEXT PROC dump (INT CONST p) : 
   IF p > 0 AND p <= 100 THEN dump entry (param field (p)) 
                         ELSE param nr out of range 
    FI 
ENDPROC dump ; 
 
TEXT PROC dump entry (PARAMDESCRIPTOR CONST id) : 
(*  object name :=  dump (id.type) ; *)
    object name :=  "TYPE " ;           (*  siehe                         *)
    object name CAT dump (id.type) ;    (*    TEXT PROC dump (DTYPE d)    *)
    object name CAT text (id.access) ; 
    object name CAT dump (id.addr) ; 
    object name CAT dump (id.push opn) ;
    object name
ENDPROC dump entry ; 

 
#page#
(**************************************************************************) 
(*                                                                        *) 
(*                  7. Datentypen   Teil II                   08.09.1986  *) 
(*                                                                        *) 
(*   Deklaration neuer Datentypen                                         *) 
(*   Vergleich von DTYPEs im Parameterfeld und in der Permanent-Tabelle   *) 
(*                                                                        *) 
(**************************************************************************) 



DTYPE VAR pt type ;

PROC declare (TEXT CONST name, INT CONST size, align, DTYPE VAR type) : 
    entry into name table ; 
    put next permanent (permanent type) ; 
    put next permanent (size) ; 
    put next permanent (nt link) ;
    mark no offsets of text elements . 
 
entry into name table : 
    declare object (name, nt link, CONCR (type)) ;
    CONCR (type) DECR begin of permanent table .
 
mark no offsets of text elements : 
    put next permanent (0) 
ENDPROC declare ; 
 
BOOL PROC same type (INT CONST param 1, param 2) : 
    INT CONST left type :: CONCR (param field [param 1].type) ;
    IF left type = right type
       THEN same fine structure if there is one
       ELSE left type = undefined id OR right type = undefined id
    FI .
 
right type : CONCR (param field [param 2].type) . 
 
same fine structure if there is one : 
    IF   left type = row id     THEN compare row 
    ELIF left is struct or proc THEN compare struct 
                                ELSE TRUE 
    FI . 
 
left is struct or proc :
    left type = struct id OR left type = proc id .

compare row : 
    equal sizes AND same type (param1 + 1, param2 + 1) . 
 
equal sizes : 
    param field [param1+1].access = param field [param2+1].access .
 
compare struct : 
    INT VAR p1 :: param1+1, p2 :: param2+1 ; 
    WHILE same type (p1, p2) AND NOT end type found REP
       NEXTPARAM p1 ;
       NEXTPARAM p2
    UNTIL end of field PER ;
    FALSE .

end type found :
    CONCR (param field [p1].type) = end id .

end of field : 
    p1 > size of param field OR p2 > size of param field 
ENDPROC same type ;
 
BOOL PROC same type (INT CONST param nr, DTYPE CONST type) : 
    field pointer := param nr ;
    CONCR (pt type) := CONCR (type) ;
    equal types 
ENDPROC same type ;

BOOL PROC equal types :
    identical types OR one type is undefined .

one type is undefined :
    type of actual field = undefined id OR CONCR(pt type) = undefined id .

identical types :
    SELECT type class (pt type) OF 
        CASE 0, 1, 2 : type of actual field = CONCR (pt type)
        CASE 3       : perhaps equal rows
        CASE 4       : perhaps equal structs
        CASE 5       : perhaps equal param procs
        OTHERWISE      FALSE
    ENDSELECT .

perhaps equal rows :
    param link := CONCR (pt type) + begin of pt minus ptt limit ;
    is row AND equal row sizes AND equal row types . 
 
is row :
    type of actual field = row id .

perhaps equal structs : 
    param link := CONCR (pt type) + begin of pt minus ptt limit ;
    is struct AND same type fields . 
 
is struct :
    type of actual field = struct id .

equal row sizes :
    pt row size = row size within param field . 

equal row types :
    field pointer INCR 1 ;
    param link INCR 2 ;
    get type and mode (CONCR(pt type)) ;
    equal types .

pt row size :
    cdb int (param link + 1) .

row size within param field :
    param field [field pointer + 1].access .
 
same type fields :
    REP
        field pointer INCR 1 ;
        param link INCR 1 ;
        IF type of actual field = end id
             THEN LEAVE same type fields WITH pt struct end reached
        FI ; 
        get type and mode (CONCR(pt type)) ;
        IF NOT equal types THEN LEAVE same type fields WITH FALSE FI
    UNTIL end of field PER ;
    FALSE .

pt struct end reached : 
    cdbint (param link) = permanent type field . 
 
end of field :
    field pointer > size of param field .

type of actual field :
    CONCR (param field [field pointer].type) .

perhaps equal param procs :
    param link := CONCR (pt type) + begin of pt minus ptt limit ;
    is proc AND same param list . 

is proc : cdbint (param link) = permanent param proc .

same param list :
    param link INCR wordlength ;
    DTYPE VAR proc result type ;
    get type and mode (CONCR (proc result type)) ;
    compare param list ;
    check results .

compare param list :
    INT VAR last param := field pointer + 1 ;
    REP
        field pointer INCR 1 ;
        param link INCR wordlength ;
        IF pt param list exhausted THEN LEAVE compare param list FI ; 
        IF type of actual field = end id 
           THEN LEAVE equal types WITH FALSE
        FI ; 
        get type and mode (CONCR(pt type)) ;
        last param := field pointer ;
    UNTIL NOT equal types OR end of field PER .

check results : 
    pt param list exhausted AND equal result types .

equal result types :
    save param link ;
    IF same type (last param, proc result type)
       THEN restore ;
            TRUE
       ELSE FALSE
    FI .

pt param list exhausted :
    cdbint (param link) = permanent param proc end marker .

save param link :
    INT CONST p :: param link .

restore :
    field pointer INCR 1 ;
    param link := p

ENDPROC equal types ;

BOOL PROC is not void bool or undefined (DTYPE CONST dtype) :
    type <> void id AND type <> bool result id AND type <> undefined id .

type : CONCR (dtype)
ENDPROC is not void bool or undefined ;
 

#page#
(**************************************************************************) 
(*                                                                        *) 
(*                  8. Operationen  Teil II                   08.09.1986  *) 
(*                                                                        *) 
(*   Definition der Opcodes                                               *) 
(*   Deklaration, Definition, Identifikation und Applikation              *) 
(*   Eroeffnen und Schliessen eines Moduls                                *)
(*                                                                        *) 
(**************************************************************************) 
 
 
 
LET module not opened  = "Module not opened" , 
    define missing     = "DEFINE missing" ,
    wrong nr of params = "Wrong Nr. of Params:" , 
    illegal kind       = "Opcode expected" ,
    nested module      = "Nested Modules" ,
    no mod nr          = "Param Proc expected" ,
    no immediate value = "Value expected" ,
    type error         = "Type Error" ,
 
    q ln              =  1 ,
    q move            =  2 ,    q move code             =  2 048 ,
    q inc1            =  3 ,    q inc1 code             =  3 072 ,
    q dec1            =  4 ,    q dec1 code             =  4 096 ,
    q inc             =  5 ,    q inc code              =  5 120 ,
    q dec             =  6 ,    q dec code              =  6 144 ,
    q add             =  7 ,    q add code              =  7 168 ,
    q sub             =  8 ,    q sub code              =  8 192 ,
    q clear           =  9 ,    q clear code            =  9 216 ,
    q test            = 10 , 
    q equ             = 11 ,    q equ code              = 11 264 , 
    q lsequ           = 12 ,    q lsequ code            = 12 288 , 
    q fmove           = 13 ,    q fmove code            = 13 312 , 
    q fadd            = 14 ,    q fadd code             = 14 336 , 
    q fsub            = 15 ,    q fsub code             = 15 360 , 
    q fmult           = 16 ,    q fmult code            = 16 384 , 
    q fdiv            = 17 ,    q fdiv code             = 17 408 ,
    q flsequ          = 18 ,    q flsequ code           = 18 432 ,
    q tmove           = 19 ,    q tmove code            = 19 456 ,
    q tequ            = 20 ,    q tequ code             = 20 480 , 
    q accds           = 21 ,    q access ds code        = 22 528 , 
    q ref             = 22 ,    q ref code              = 23 552 ,
    q subscript       = 23 ,    q subscript code        = 24 576 , 
    q select          = 24 ,    q select code           = 25 600 ,
    q ppv             = 25 ,    q ppv code              = 26 624 ,
    q pp              = 26 , 
    q make false      = 27 , (* q make false code       = 65 513 *)
    q movex           = 28 ,
(*  q longa subs                q longa subs code       = 65 376 *) 
    q return          = 29 ,    q return code           = 32 512 ,
    q true return     = 30 ,    q true return code      = 32 513 ,
    q false return    = 31 ,    q false return code     = 32 514 ,
                                q goret code            = 32 519 ,
    q esc mult        = 32 ,    q esc mult code         = 32 553 ,
    q esc div         = 33 ,    q esc div code          = 32 554 , 
    q esc mod         = 34 ,    q esc mod code          = 32 555 , 
    q pproc           = 35 , 
    q compl int       = 36 ,    q compl int code        = 32 551 ,
    q compl real      = 37 ,    q compl real code       = 32 550 ,
    q alias ds        = 38 ,    q alias ds code         = 32 546 ,
    q movim           = 39 ,    q esc movim code        = 32 547 ,
    q fequ            = 40 ,    q fequ code             = 32 548 ,
    q tlsequ          = 41 ,    q tlsequ code           = 32 549 ,
(*  q case            = 42 , *) q esc case              = 32 544 ,
    q plus            = 43 ,
    q minus           = 44 ,
    q mult            = 45 ,
    q int div         = 46 ,
    q real div        = 47 ,
    q equal           = 48 ,
    q lessequal       = 49 ,
    q ulseq           = 50 ,    q ulseq code            = 21 504 ,
    q pdadd           = 51 ,    q pdadd code            = 32 653 ,
    q ppsub           = 52 ,    q ppsub code            = 32 654 ,
    q dimov           = 53 ,    q dimov code            = 32 655 ,
    q idmov           = 54 ,    q idmov code            = 32 656 ;

INT CONST q make false code :: - 1 022 , 
          q longa subs code :: -   159 ,
          q penter code     :: -   511 ;
 

                   (***** Deklaration *****) 
 
PROC declare (OPN VAR operation) : 
    operation.kind := proc op ;
    get module nr (operation.mod nr) ; 
    operation.top of stack := 0 
ENDPROC declare ; 
 
PROC declare (TEXT CONST name, INT CONST first, params, OPN VAR operation) : 
    declare (operation) ;
    entry into name and pt table if necessary ; 
    enter params ; 
    enter result ; 
    enter module number . 
 
entry into name and pt table if necessary : 
    declare object (name, nt link, permanent pointer) . 
 
enter params : 
    field pointer := first ;
    FOR index FROM 1 UPTO params REP
       enter param (param field [field pointer]) ;
       NEXTPARAM field pointer 
    PER .
 
enter result : 
    enter param (param field[field pointer].type, permanent proc op) .
 
enter module number : 
    put next permanent (operation.mod nr)
ENDPROC declare ; 
 
PROC enter param (PARAMDESCRIPTOR CONST param) :
    IF   param.access = const 
         THEN enter param (param.type, permanent param const)
    ELIF param.access = var 
         THEN enter param (param.type, permanent param var)
    ELSE errorstop ("Unknown Access")
    FI
ENDPROC enter param ;

PROC enter param (DTYPE CONST type, INT CONST permanent mode) :
    unsigned arithmetic ;
    SELECT type class (type) OF
        CASE 0, 1, 2 : put next permanent (CONCR(type) + permanent mode)
        OTHERWISE      errorstop ("Illegal Type")
    ENDSELECT
ENDPROC enter param ;


                    (***** Definition *****) 
 
PROC define (OPN VAR opn) : 
    IF NOT module open THEN errorstop (module not opened)
                       ELSE proc head (opn.mod nr, opn.top of stack)
    FI 
ENDPROC define ; 
 
PROC set length of local storage (OPN VAR opn, INT CONST size) :
    IF   size < 0 OR size > local address limit
         THEN errorstop (address overflow)
    ELIF opn.top of stack = 0
         THEN errorstop (define missing)
    ELIF opn.kind <> proc op
         THEN errorstop (proc op expected)
    FI ;
    set length (opn.top of stack, size + eumel0 stack offset)
ENDPROC set length of local storage ; 
 
PROC define (OPN VAR operation, INT CONST size) : 
    define (operation) ; 
    set length of local storage (operation, size)
ENDPROC define ; 
 
 
                 (***** Identifikation *****) 
 
INT VAR counter, result index, result type repr;
 
PROC identify (TEXT CONST name, INT CONST first, params, OPN VAR operation,
               BOOL VAR object exists) :
    find result entry ; 
    to object (name) ;
    IF found  THEN first fit and leave if found FI ; 
    IF eumel0 THEN identify eumel0 instruction 
              ELSE yield undefined operation 
    FI .
 
find result entry : 
    result index := first; 
    counter := 0 ;
    WHILE counter < params REP 
        NEXTPARAM result index ; 
        counter INCR 1
    PER ;
    check on param field exceeded .

check on param field exceeded :
    IF result index > size of param field
       THEN errorstop (param field exceeded) 
    FI .
 
yield undefined operation :
    declare (result index, undefined type) ;
    apply (result index, nop) ;
    object exists := FALSE .
 
first fit and leave if found :
    WHILE yet another procedure exists REP 
        check one procedure and leave if match ; 
        next procedure 
    PER . 
 
yet another procedure exists : 
    permanent pointer <> 0 . 
 
check one procedure and leave if match: 
    param link := permanent pointer + wordlength ; 
    set end marker if end of list ;
    counter := params ; 
    field pointer := first ;
    REP
       IF   end of params AND counter = 0 
            THEN procedure found
       ELIF end of params OR  counter = 0 
            THEN LEAVE check one procedure and leave if match 
            ELSE check next param 
       FI 
   PER . 
 
check next param : 
    get type and mode (CONCR(pt type)) ;
    IF same types THEN set param mode ; 
                       field pointer INCR 1 ;
                       param link INCR 1 ;
                       set end marker if end of list ;
                       counter DECR 1 ; 
                  ELSE LEAVE check one procedure and leave if match 
    FI . 
 
same types : (* inline version ! *)
    equal types .
 
set param mode : 
    param field [field pointer].access := mode . 
 
procedure found : 
    get result ; 
    operation.kind   := proc op ; 
    operation.mod nr := module number ; 
    operation.top of stack := 0 ;
    object exists := TRUE ;
    LEAVE identify . 
 
get result : 
    get type and mode (result type) ; 
    declare (result index, mode) .
 
module number :
    cdbint (param link + 1) . 

result type :
    CONCR (param field [result index].type) .
 
eumel0 : 
    eumel0 opn.mod nr := link (eumel 0 opcodes, name) ; 
    eumel0 opn.mod nr <> 0 .
 
identify eumel 0 instruction : 
    init result type with void ; 
    CONCR (operation) := CONCR (eumel0 opn) ;
    object exists := check params and set result ;
    declare (result index, DTYPE:(result type repr)) ;
    declare (result index, const) .

init result type with void :
    result type repr := void id . 
 
check params and set result :
    SELECT operation.mod nr OF
       CASE q return, q false return, q true return : no params 
       CASE q inc1, q dec1          : one int param yielding void 
       CASE q pproc, q pp, q ln     : one param yielding void
       CASE q test                  : one param yielding bool
       CASE q clear, q ppv          : one int or bool param yielding void 
       CASE q make false            : one bool param yielding void 
       CASE q move                  : two int or bool params yielding void 
       CASE q compl int, q inc, q dec : two int params yielding void
       CASE q compl real, q fmove   : two real params yielding void 
       CASE q equ, q lsequ, q ulseq : two int params yielding bool 
       CASE q fequ, q flsequ        : two real params yielding bool 
       CASE q tequ, q tlsequ        : two text params yielding bool
       CASE q tmove                 : two text params yielding void
       CASE q accds, q ref, q movim,
            q dimov, q idmov        : two params yielding void
       CASE q add, q sub, q esc mult,
            q esc div, q esc mod    : three int params yielding void
       CASE q fadd, q fsub, q fmult, q fdiv : three real params yielding void
       CASE q select, q movex, q alias ds,
            q pdadd, q ppsub        : three params 
       CASE q subscript             : five params 
       CASE q plus, q mult          : two intreals yielding intreal
       CASE q minus                 : monadic or dyadic minus
       CASE q int div               : two int params yielding int 
       CASE q real div              : two real params yielding real
       CASE q equal, q lessequal    : two intrealtexts yielding bool
       OTHERWISE                      FALSE
    ENDSELECT .
 
no params : 
    params = 0 . 

one int param yielding void : 
    p1 void (int type, first, params) .

one param yielding void :
    params = 1 . 

one param yielding bool :
    IF params = 1 THEN result type repr := bool id ; 
                       TRUE 
                  ELSE FALSE
    FI .
 
one int or bool param yielding void :
    p1 void (int type, first, params) OR p1 void (bool type, first, params) . 

one bool param yielding void :
    p1 void (bool type, first, params) . 
 
two int or bool params yielding void : 
    p2 (int  type, first, params, void id) OR
    p2 (bool type, first, params, void id) .

two int params yielding void :
    p2 (int type, first, params, void id) .

two real params yielding void :
    p2 (real type, first, params, void id) .

two text params yielding void :
    p2 (text type, first, params, void id) .

two int params yielding bool :
    p2 (int type, first, params, bool id) .

two real params yielding bool :
    p2 (real type, first, params, bool id) .

two text params yielding bool :
    p2 (text type, first, params, bool id) .

two params yielding void :
    params = 2 . 

three int params yielding void :
    p3 void (int type, first, params) .

three real params yielding void :
    p3 void (real type, first, params) .

three params :
    params = 3 .

five params : 
    params = 5 . 

two intreals yielding intreal :
    two int params yielding int OR two real params yielding real .

monadic or dyadic minus :
    IF   params = 2 THEN two intreals yielding intreal
    ELIF params = 1 THEN monadic minus
                    ELSE FALSE
    FI .

monadic minus :
    result type repr := CONCR (param field[first].type) ;
    result type repr = int id OR result type repr = real id .

two intrealtexts yielding bool :
    two int params yielding bool OR two real params yielding bool OR
    two text params yielding bool .

two int params yielding int :
    p2 (int type, first, params, int id) .

two real params yielding real :
    p2 (real type, first, params, real id)
ENDPROC identify ; 
 
BOOL PROC p1 void (DTYPE CONST requested type, INT CONST first, param nr) :
    param nr = 1 AND param type is requested plain type . 
 
param type is requested plain type :
    CONCR (param field [first].type) = CONCR (requested type) 
 
ENDPROC p1 void ;
 
BOOL PROC p2 (DTYPE CONST requested type, INT CONST first, param nr,
              INT CONST result type) :
    IF param nr = 2 AND param types equal requested plain type
       THEN result type repr := result type ;
            TRUE
       ELSE FALSE
    FI .
 
param types equal requested plain type :
    CONCR (param field [first]  .type) = CONCR (requested type) AND 
    CONCR (param field [first+1].type) = CONCR (requested type)

ENDPROC p2 ;
 
BOOL PROC p3 void (DTYPE CONST requested type, INT CONST first, param nr) :
    param nr = 3 AND param types ok .
 
param types ok :
    FOR index FROM first UPTO first+2 REP
       IF different param types THEN LEAVE p3 void WITH FALSE FI 
    PER ;
    TRUE .
 
different param types :
    CONCR (param field [index].type) <> CONCR (requested type)
ENDPROC p3 void; 


                   (***** Applikation *****) 
 
INT VAR address representation, left repr, right repr, result repr;

PROC apply (INT CONST first, nr of params, OPN CONST opn) : 
    IF NOT module open THEN errorstop (module not opened) FI ;
    SELECT opn.kind OF 
        CASE eumel 0    : generate eumel0 instruction 
        CASE proc op    : call operation 
        CASE param proc : call param proc
        CASE nil        :
        OTHERWISE         errorstop (illegal kind) 
    ENDSELECT .
 
call operation :
    push params if necessary (first, nr of params, opn.mod nr) ; 
    call (opn.mod nr) .
 
call param proc : 
    result addr.kind := local ref ;
    result addr.value := opn.mod nr ;
    INT CONST module nr := REPR result addr ;
    push params if necessary (first, nr of params, module nr) ;
    call param (module nr) .

generate eumel0 instruction : 
    SELECT real nr of params OF 
        CASE 0 : p0 instruction 
        CASE 1 : apply p1 (opn, first addr) 
        CASE 2 : apply p2 (opn, first addr, second addr)
        CASE 3 : apply p3 (opn, left type, first addr, second addr, third addr) 
        CASE 5 : subscript operation
        OTHERWISE errorstop (wrong nr of params + text (nr of params)) 
    ENDSELECT . 
 
real nr of params :
    IF operator denotation THEN nr of params + 1
                           ELSE nr of params
    FI .

operator denotation :
    opn.mod nr >= q plus AND opn.mod nr < q ulseq .

p0 instruction :
    IF   opn.mod nr = q return       THEN s0 (q return code) 
    ELIF opn.mod nr = q true return  THEN s0 (q true return code)
    ELIF opn.mod nr = q false return THEN s0 (q false return code)
                                     ELSE errorstop (wrong nr of params +
                                                     mnemonic (opn)) 
    FI .
 
subscript operation :
    IF opn.mod nr = q subscript 
       THEN subscription
       ELSE errorstop (wrong nr of params + text (nr of params))
    FI .

subscription :
    ADDRESS CONST element length :: param field [first+2].addr ,
                  limit          :: param field [first+3].addr ;
    check on immediates ;
    IF element length.value < 1024
       THEN s0 (q subscript code + element length.value)
       ELSE s0 (q longa subs code) ;
            s0 (element length.value)
    FI ;
    s3 (limit.value - 1, subs index, base addr, subs result) .

check on immediates :
    IF element length.kind <> immediate value OR
       limit.kind <> immediate value
       THEN errorstop (no immediate value)
    FI .

subs index  : REPR param field [first+1].addr .

base addr   : REPR param field [first].addr .

subs result : REPR param field [first+4].addr .

first addr : 
    param field [first].addr .
 
left type :
    param field [first].type .

second addr : 
    param field [nextparam (first)].addr .
 
third addr : 
    param field [nextparam(nextparam(first))].addr
ENDPROC apply ;
 
PROC push params if necessary (INT CONST first, nr of params, mod nr) : 
    init param push (mod nr) ;
    field pointer := first ;
    IF nr of params > 0 THEN push params FI ;
    push result if there is one .
 
push params : 
    FOR index FROM 1 UPTO nr of params REP 
        apply p1 (push code, param addr) ; 
        NEXTPARAM field pointer
    PER . 
 
push code : 
    param field [field pointer].push opn . 
 
param addr :
    param field [field pointer].addr . 
 
push result if there is one : 
    IF push result necessary 
       THEN push result address (REPR param field [field pointer].addr)
    FI . 

push result necessary :
    param field [field pointer].push opn.kind <> nil AND 
    is not void bool or undefined (param field [field pointer].type) 
ENDPROC push params if necessary ;

PROC apply p1 (OPN CONST opn, ADDRESS CONST addr) : 
    IF   opn.mod nr = q ln    THEN generate line number 
    ELIF opn.mod nr = q pproc THEN push module nr
                              ELSE gen p1 instruction
    FI .

gen p1 instruction : 
    address representation := REPR addr ;
    SELECT opn.mod nr OF 
        CASE q inc1  : t1 (q inc1 code, address representation)
        CASE q dec1  : t1 (q dec1 code, address representation)
        CASE q clear : t1 (q clear code,address representation)
        CASE q test  : test bool object (address representation)
        CASE q pp    : push param (address representation)
        CASE q ppv   : s1 (q ppv code, address representation)
        CASE q make false : s1 (q make false code, address representation)
        OTHERWISE errorstop (wrong nr of params + mnemonic (opn))
    ENDSELECT .

generate line number :
    IF addr.kind = immediate value THEN mark line (addr.value)
                                   ELSE errorstop (no immediate value)
    FI .

push module nr : 
    IF addr.kind = module nr THEN push param proc (addr.value)
                             ELSE errorstop (no mod nr)
    FI
ENDPROC apply p1; 
 
PROC apply p2 (OPN CONST opn, ADDRESS CONST left addr, right addr): 
    left repr := REPR left addr ;
    IF opn.mod nr = q movim THEN move immediate
                            ELSE gen p2 instruction 
    FI . 
 
gen p2 instruction : 
    right repr := REPR right addr ;
    SELECT opn.mod nr OF 
        CASE q move       : t2 (q move code, right repr, left repr)
        CASE q inc        : t2 (q inc code, right repr, left repr) 
        CASE q dec        : t2 (q dec code, right repr, left repr) 
        CASE q equ        : compare (q equ code, left repr, right repr) 
        CASE q lsequ      : compare (q lsequ code, left repr, right repr) 
        CASE q ulseq      : compare (q ulseq code, left repr, right repr)
        CASE q fmove      : t2 (q fmove code, right repr, left repr)
        CASE q flsequ     : compare (q flsequ code, left repr, right repr) 
        CASE q tmove      : t2 (q tmove code, right repr, left repr)
        CASE q tequ       : compare (q tequ code, left repr, right repr) 
        CASE q compl int  : s2 (q compl int code, left repr, right repr)
        CASE q compl real : s2 (q compl real code, left repr, right repr)
        CASE q fequ       : compare (q fequ code, left repr, right repr) 
        CASE q tlsequ     : compare (q tlsequ code, left repr, right repr) 
        CASE q accds      : t2 (q access ds code, left repr, right repr)
        CASE q ref        : t2 (q ref code, left repr, right repr) 
        CASE q dimov      : s2 (q dimov code, left repr, right repr)
        CASE q idmov      : s2 (q idmov code, left repr, right repr)
        OTHERWISE errorstop (wrong nr of params + mnemonic (opn))
    ENDSELECT .
 
move immediate :
    IF right addr.kind = immediate value 
       THEN s0 (q esc movim code) ;
            s1 (right addr.value, left repr)
       ELSE errorstop (no immediate value)
    FI
ENDPROC apply p2; 
 
PROC apply p3 (OPN CONST opn, DTYPE CONST left dtype, 
               ADDRESS CONST left addr, right addr, result addr ):
    result repr := REPR result addr ;
    IF   opn.mod nr = q pdadd  THEN select with dint; LEAVE apply p3
    ELIF opn.mod nr = q select THEN gen select instruction; LEAVE apply p3 FI ;
    left repr   := REPR left addr ; 
    IF   opn.mod nr = q movex    THEN gen long move
    ELIF opn.mod nr = q alias ds THEN alias dataspace
                                 ELSE gen p3 instruction
    FI .

gen long move :
    IF right addr.kind = immediate value
       THEN long move (left repr, result repr, right addr.value)
       ELSE errorstop (no immediate value)
    FI .

alias dataspace :
    IF right addr.value = immediate value
       THEN s0 (q alias ds code) ;
            s2 (right addr.value, result repr, left repr)
       ELSE errorstop (no immediate value)
    FI .

gen select instruction :
    IF right addr.kind = immediate value 
       THEN IF different bases
               THEN access external (left addr.value, right addr.value)
               ELSE t1 (q select code, REPR left addr) ;
                    s1 (right addr.value, result repr)
            FI
       ELSE errorstop (no immediate value)
    FI .

select with dint :
    right repr := REPR right addr ;
    IF different bases THEN access external packet
                       ELSE simple access
    FI .

different bases :
    left addr.kind = p base AND left addr.value <> packet base .

simple access :
    s3 (q pdadd code, REPR left addr, right repr, result repr) .

access external packet :
    access external (left addr.value, global address zero) ;
    s3 (q pdadd code, REPR REF result addr, right repr, result repr) .

gen p3 instruction :
    right repr  := REPR right addr ; 
    SELECT opn.mod nr OF 
        CASE q add                : int add
        CASE q sub                : int sub
        CASE q fadd               : real add 
        CASE q fsub               : real sub 
        CASE q fmult              : real mult 
        CASE q fdiv, q real div   : real div 
        CASE q esc mult           : int mult 
        CASE q esc div, q int div : int div 
        CASE q esc mod            : int mod 
        CASE q plus               : int real add
        CASE q minus              : int real sub
        CASE q mult               : int real mult
        CASE q equal, q lessequal : compare (comp code, left repr, right repr)
        CASE q ppsub              : distance between two objects
        OTHERWISE errorstop (wrong nr of params + mnemonic (opn))
    ENDSELECT . 
 
int add   : compute (q add code, left repr, right repr, result repr) . 
 
int sub   : compute (q sub code, left repr, right repr, result repr) . 
 
real add  : compute (q fadd code, left repr, right repr, result repr) . 
 
real sub  : compute (q fsub code, left repr, right repr, result repr) . 
 
real mult : compute (q fmult code, left repr, right repr, result repr) . 
 
real div  : compute (q fdiv code, left repr, right repr, result repr) . 
 
int mult  : s3 (q esc mult code, left repr, right repr, result repr) . 
 
int div   : s3 (q esc div code, left repr, right repr, result repr) . 
 
int mod   : s3 (q esc mod code, left repr, right repr, result repr) .
 
int real add : 
    IF left type = int id THEN int add
                          ELSE real add
    FI . 
 
int real sub :
    IF left type = int id THEN int sub 
                           ELSE real sub
    FI .

int real mult :
    IF left type = int id THEN int mult
                          ELSE real mult
    FI . 

comp code : 
    SELECT left type OF
        CASE int id    : IF opn.mod nr = q equal THEN q equ  ELSE q lsequ FI 
        CASE real id   : IF opn.mod nr = q equal THEN q fequ ELSE q flsequ FI
        CASE string id : IF opn.mod nr = q equal THEN q tequ ELSE q tlsequ FI
        OTHERWISE errorstop (type error); q equ
    ENDSELECT .

left type : CONCR (left dtype) .

distance between two objects :
    s3 (q ppsub code, left repr, right repr, result repr)

ENDPROC apply p3; 
 
PROC access external (INT CONST old base, offset) :
    s0 (q penter code + old base) ;
    t2 (q ref code, offset, result repr) ;
    s0 (q penter code + packet base)
ENDPROC access external ;


                      (***** Modul *****) 
 
BOOL VAR module open ;

.init opn section : 
    module open := FALSE .;

PROC begin module : 
    IF module open THEN errorstop (nested module) 
                   ELSE begin modul ; 
                        module open := TRUE 
    FI 
ENDPROC begin module ; 
 
PROC end module : 
    IF NOT module open
       THEN errorstop (module not opened) 
       ELSE end modul ;
            module open := FALSE
    FI
ENDPROC end module ; 

TEXT PROC dump (OPN CONST operation) : 
    IF   operation.kind = proc op THEN " PROC" + text (operation.mod nr, 5) 
    ELIF operation.kind = eumel 0 THEN " EUMEL0: " + mnemonic (operation)
                                  ELSE " undef. Opn" 
    FI 
ENDPROC dump ; 
 
PROC begin modul :
    EXTERNAL 10073
ENDPROC begin modul ; 
 
PROC end modul :
    EXTERNAL 10011
ENDPROC end modul ; 
 
PROC proc head (INT VAR mod nr, top of stack) :
    EXTERNAL 10012
ENDPROC proc head ; 
 
PROC set length (INT CONST top of stack, size) : 
    EXTERNAL 10013
ENDPROC set length ; 
 
PROC get module nr (INT VAR module nr) : 
    EXTERNAL 10016
ENDPROC get module nr ; 
 
PROC compute (INT CONST op code, l addr, r addr, result address) :
    EXTERNAL 10017
ENDPROC compute ; 
 
PROC compare (INT CONST op code, l addr, r addr) :
    EXTERNAL 10018
ENDPROC compare ; 
 
PROC long move (INT CONST to, from, length) :
    EXTERNAL 10019
ENDPROC long move ;

PROC call (INT CONST mod nr) : 
    EXTERNAL 10022
ENDPROC call ; 
 
PROC call param (INT CONST mod nr) : 
    EXTERNAL 10023
ENDPROC call param ; 
 
PROC push param (INT CONST addr) : 
    EXTERNAL 10024
ENDPROC push param ; 
 
PROC push param proc (INT CONST mod nr) : 
    EXTERNAL 10025
ENDPROC push param proc ; 
 
PROC init param push (INT CONST mod nr) : 
    EXTERNAL 10026
ENDPROC init param push ; 
 
PROC push result address (INT CONST addr) : 
    EXTERNAL 10027
ENDPROC push result address ; 
 
PROC test bool object (INT CONST addr) : 
    EXTERNAL 10192
ENDPROC test bool object ; 
 
PROC mark line (INT CONST line number) : 
    EXTERNAL 10030
ENDPROC mark line ; 
 
PROC s0 (INT CONST op code) : 
    EXTERNAL 10038
ENDPROC s0 ; 
 
PROC s1 (INT CONST op code, addr) : 
    EXTERNAL 10039
ENDPROC s1 ; 
 
PROC s2 (INT CONST op code , addr1, addr2) : 
    EXTERNAL 10040
ENDPROC s2 ; 
 
PROC s3 (INT CONST op code, addr1, addr2, addr3) : 
    EXTERNAL 10041
ENDPROC s3 ; 
 
PROC t1 (INT CONST op code, addr) : 
    EXTERNAL 10042
ENDPROC t1 ; 
 
PROC t2 (INT CONST op code, addr1, addr2) : 
    EXTERNAL 10043
ENDPROC t2 ; 
 
#page#
(**************************************************************************) 
(*                                                                        *) 
(*                  9. Speicherverwaltung                     03.06.1986  *) 
(*                                                                        *) 
(*   Ablage der Paketdaten                                                *) 
(*                                                                        *) 
(**************************************************************************) 



INT VAR address value;
 
INT CONST data allocation by coder  := 1 , 
          data allocation by user   := 2 ; 

LET not initialized      = 0 ,
    wrong mm mode        = "Wrong MM Mode" ,
    define on non global = "Define for GLOB only" ,
    text too long        = "TEXT too long" ;
 
TEXT VAR const buffer :: point line ;

.reset memory management mode :
     memory management mode := not initialized . ;
 
PROC reserve storage (INT CONST size) : 
    IF memory management mode <> data allocation by user 
       THEN errorstop (wrong mm mode) 
    FI ; 
    allocate var (address value, size) ; 
    memory management mode := not initialized
ENDPROC reserve storage ; 
 
PROC allocate variable (ADDRESS VAR addr, INT CONST size) : 
    IF memory management mode <> data allocation by coder 
       THEN errorstop (wrong mm mode) 
    FI ; 
    allocate var (addr.value, size) ;
    addr.kind := global
ENDPROC allocate variable ; 
 
PROC allocate denoter (ADDRESS VAR addr, INT CONST value) :
    IF memory management mode <> data allocation by coder 
       THEN errorstop (wrong mm mode) 
    FI ; 
    allocate int denoter (addr.value) ;
    put data word (value, addr.value) ;
    addr.kind := global
ENDPROC allocate denoter ; 

PROC allocate denoter (ADDRESS VAR addr, REAL CONST value) :
    IF memory management mode <> data allocation by coder 
       THEN errorstop (wrong mm mode) 
    FI ; 
    allocate real denoter (addr.value) ;
    addr.kind := global ;
    define (addr, value)
ENDPROC allocate denoter ; 
 
PROC allocate denoter (ADDRESS VAR addr, TEXT CONST value) :
    IF memory management mode <> data allocation by coder 
       THEN errorstop (wrong mm mode) 
    FI ; 
    allocate text denoter (addr.value, (LENGTH value+1) DIV 2 + 2) ; 
    addr.kind := global ;
    skip heaplink; 
    define (addr, value) ; 
    reset heaplink .
 
skip heaplink : 
    addr.value INCR 1 .

reset heaplink :
    addr.value DECR 1
ENDPROC allocate denoter ; 
 
PROC allocate denoter (ADDRESS VAR addr, DINT CONST value) :
    IF memory management mode <> data allocation by coder 
       THEN errorstop (wrong mm mode) 
    FI ; 
    allocate dint denoter (addr.value, value) ;
    addr.kind := global
ENDPROC allocate denoter ;

PROC allocate dint denoter (INT VAR addr offset, DINT CONST value) :
    adjust to an even address if necessary ;
    put data word (value.low, addr offset) ;
    allocate int denoter (address value) ;
    put data word (value.high, address value) .

adjust to an even address if necessary :
    allocate int denoter (addr offset) ;
    IF (addr offset AND 1) <> 0 THEN allocate int denoter (addr offset) FI
ENDPROC allocate dint denoter ; 

PROC define (ADDRESS CONST addr, INT CONST value) : 
    IF addr.kind <> global 
       THEN errorstop (define on non global) 
    FI ; 
    put data word (value, addr.value) 
ENDPROC define ; 
 
PROC define (ADDRESS CONST addr, DINT CONST value) : 
    IF addr.kind <> global
       THEN errorstop (define on non global) 
    FI ; 
    put data word (value.low , addr.value);
    put data word (value.high, addr.value + 1)
ENDPROC define ;

PROC define (ADDRESS CONST addr, REAL CONST value) : 
    IF addr.kind <> global 
       THEN errorstop (define on non global) 
    FI ; 
    replace (const buffer, 1, value) ; 
    address value := addr.value ;
    FOR index FROM 1 UPTO 4 REP 
        put data word (const buffer ISUB index, address value) ;
        address value INCR 1
    PER 
ENDPROC define ; 
 
PROC define (ADDRESS CONST addr, TEXT CONST value) : 
    IF   addr.kind <> global THEN errorstop (define on non global) 
    ELIF LENGTH value > 255  THEN errorstop (text too long)
    FI ; 
    address value := addr.value ;
    const buffer := code (LENGTH value) ; 
    const buffer CAT value ; 
    const buffer CAT ""0"" ;
    FOR index FROM 1 UPTO LENGTH const buffer DIV 2 REP 
        put data word (const buffer ISUB index, address value) ;
        address value INCR 1
    PER ; 
    const buffer := point line
ENDPROC define ; 
 
PROC allocate var (INT VAR addr, INT CONST length) : 
    EXTERNAL 10033
ENDPROC allocate var ; 
 
PROC allocate int denoter (INT VAR addr) : 
    EXTERNAL 10034
ENDPROC allocate int denoter ;
 
PROC allocate real denoter (INT VAR addr) : 
    EXTERNAL 10035 
ENDPROC allocate real denoter ;

PROC allocate text denoter (INT VAR addr, INT CONST length) : 
    EXTERNAL 10036 
ENDPROC allocate text denoter ;
 
PROC put data word (INT CONST value, INT CONST addr) :
    EXTERNAL 10037
ENDPROC put data word ; 
 
 
#page#
(**************************************************************************) 
(*                                                                        *) 
(*                 10. Inspector                              28.10.1987  *) 
(*                                                                        *) 
(**************************************************************************) 



INT VAR line number, pattern length, begin of packet,
        last packet entry, indentation;

TEXT VAR bulletin name, type and mode, pattern, buffer, dummy name;
 
DATASPACE VAR bulletin ds :: nilspace ;

.packet name :
     cdb text (cdb int(packet link + wordlength) + two word length) .

.packet entry :
     permanent pointer = 0 OR
     cdbint (permanent pointer) = permanent packet OR
     cdbint (permanent pointer + wordlength) = permanent packet .

.within editor :
    aktueller editor > 0 .  ;

TEXT PROC type name (DTYPE CONST type) : 
    type and mode := "" ; 
    IF CONCR (type) = void id THEN type and mode CAT "VOID"
                              ELSE name of type (CONCR (type)) 
    FI ;
    type and mode
ENDPROC type name ; 
 
TEXT PROC dump (DTYPE CONST type) :
(*  type and mode := "TYPE " ;
    name of type (CONCR (type)) ; 
    type and mode
*)
    type name (type)    (* aus Kompatibilit√§tsgr√ľnden zum 1.9.2 Coder / rr *)
ENDPROC dump ;

PROC name of type (INT CONST type) :
            SELECT type OF
     CASE void id                 :
     CASE int id                  : type and mode CAT "INT"
     CASE real id                 : type and mode CAT "REAL"
     CASE string id               : type and mode CAT "TEXT"
     CASE bool id, bool result id : type and mode CAT "BOOL"
     CASE dataspace id            : type and mode CAT "DATASPACE"
     CASE row id                  : type and mode CAT "ROW "
     CASE struct id               : type and mode CAT "STRUCT"
     OTHERWISE                    : complex type
            ENDSELECT .

complex type :
     unsigned arithmetic ;
     IF type > ptt limit THEN perhaps permanent struct or row
                         ELSE get complex type
     FI .

perhaps permanent struct or row :
     index := type + begin of pt minus ptt limit ;
     mode := cdb int (index) MOD ptt limit ;
     IF   mode = permanent row    THEN get permanent row 
     ELIF mode = permanent struct THEN get permanent struct
                                  ELSE type and mode CAT "-"
     FI .

get complex type :
     index := type + begin of permanent table ;
     IF is complex type THEN get name
                        ELSE type and mode CAT "-"
     FI .

is complex type :
     permanent type definition mode = permanent type .

get name :
     type and mode CAT cdb text (link to type name + two word length) .

link to type name :
     cdb int (index + three word length) .

permanent type definition mode :
     cdb int (index + wordlength) .

get permanent row :
     INT VAR t; 
     type and mode CAT "ROW " ;
     type and mode CAT text (cdb int (index + wordlength)) ;
     type and mode CAT " " ;
     param link := index + two wordlength ;
     get type and mode (t) ;
     name of type (t) .
 
get permanent struct :
     type and mode CAT "STRUCT ( ... )" 
ENDPROC name of type ;

PROC help (TEXT CONST proc name) :
     prep bulletin ;
     prep help ;
     scan (object name) ;
     next symbol (pattern) ;
     packet link := end of permanent table ;
     IF function = 0 THEN standard help
                     ELSE asterisk help
     FI .

prep help :
     object name := compress (proc name) ;
     INT VAR function :: 0 ;
     INT CONST l :: LENGTH object name ;
     IF l > 1 AND object name <> "**"
        THEN IF (object name SUB l) = "*"
               THEN function INCR 2 ;
                    delete char (object name, l)
             FI ;
             IF (object name SUB 1) = "*"
               THEN function INCR 1 ;
                    delete char (object name, 1)
             FI ;
             IF another asterisk THEN wrong function FI
     FI.

another asterisk :
     pos (object name, "*") <> 0 .

wrong function :
     errorstop ("unzulaessige Sternfunktion") .

standard help :
     to object (pattern) ;
     IF found THEN display
              ELSE error stop ("unbekannt: " + proc name)
     FI .

display :
     IF NOT packet entry
        THEN WHILE permanent pointer <> 0 REP
                 put name of packet if necessary ;
                 put specifications (pattern) ;
                 next procedure
             ENDREP ;
             show bulletin file
        FI .
 
put name of packet if necessary :
     IF new packet THEN packet link := permanent pointer ;
                        find begin of packet ;
                        writeline (2) ;
                        write packet name
     FI .

find begin of packet :
     REP 
         packet link DECR wordlength
     UNTIL begin of packet found PER .

begin of packet found :
     cdb int (packet link) = permanent packet .

new packet :
     permanent pointer < packet link .

asterisk help :
     hash table pointer := begin of hash table ;
     pattern length := LENGTH pattern - 1 ;
     REP
        list all objects in current hash table chain ;
        next hash entry
     UNTIL end of hash table reached ENDREP ;
     show bulletin file .

list all objects in current hash table chain :
     nt link := hash table pointer ;
     WHILE yet another nt entry REP
        permanent pointer := cdb int (nt link + wordlength) ;
        object name := cdb text (nt link + two word length) ;
        IF matching THEN into bulletin FI
     PER .

matching :
     INT CONST p :: pos (object name, pattern) ;
     SELECT function OF
         CASE 1 :   p <> 0 AND p = LENGTH object name - pattern length
         CASE 2 :   p = 1
         CASE 3 :   p <> 0
         OTHERWISE  FALSE
     ENDSELECT .

into bulletin :
     object names into bulletin (BOOL PROC not end of chain)
ENDPROC help ;
 
BOOL PROC not end of chain :
     permanent pointer <> 0 
ENDPROC not end of chain ;

PROC write packet name :
     indentation := 0 ;
     write line ;
     write bulletin line ("PACKET ") ;
     indentation := 7 ;
     object name := packet name ;
     write bulletin line (object name) ;
     write bulletin line (":") ;
     writeline (2)
ENDPROC write packet name ;

PROC put specifications (TEXT CONST proc name) :
     put obj name (proc name) ;
     to first param ;
     IF NOT end of params THEN put param list FI ;
     put result ;
     writeline .
  
to first param :
     param link := permanent pointer + word length ;
     set end marker if end of list .

put result :
     INT VAR type;
     get type and mode (type) ;
     IF type <> void id THEN type and mode := "  --> " ;
                             name of type (type) ;
                             write bulletin line (type and mode)
     FI
ENDPROC put specifications ;

PROC put param list : 
     write bulletin line (" (") ;
     REP
         INT VAR type, param mode;
         get type and mode (type) ;
         param mode := mode ;
         put type and mode ;
         maybe param proc ;
         next pt param ;
         IF end of params THEN write bulletin line (")") ;
                               LEAVE put param list 
         FI ;
         write bulletin line (", ") ;
     PER .

put type and mode :
     type and mode := "" ;
     name of type (type) ;
     type and mode CAT name of mode ;
     write bulletin line (type and mode) .

name of mode :
     IF   param mode = const THEN " CONST"
     ELIF param mode = var   THEN " VAR"
                             ELSE " PROC"
     FI .

maybe param proc :
     IF mode = permanent param proc THEN put virtual params FI .

put virtual params :
     skip over result type if complex type ;
     IF NOT end of virtual params THEN put param list FI.

skip over result type if complex type :
     next pt param .

end of virtual params :
    end of params
ENDPROC put param list ;

PROC to packet (TEXT CONST packet name) :
     to object ( packet name) ;
     IF found THEN find start of packet objects FI .

find start of packet objects :
     last packet entry := 0 ;
     packet link := before first pt entry ;
     REP
         packet link INCR wordlength ;
         word := cdb int (packet link) ;
         IF word < 0 THEN IF   word = permanent packet THEN packet found
                          ELIF word = permanent end    THEN return
                          FI
         FI
     ENDREP .

packet found :
     IF cdb int (packet link + wordlength) = nt link
        THEN last packet entry := packet link FI .

return : 
     IF last packet entry <> 0 THEN found := TRUE ;
                                    packet link := last packet entry
                               ELSE found := FALSE
     FI ;
     LEAVE to packet
ENDPROC to packet ;

PROC next packet :
     REP
         packet link INCR wordlength ;
         word := cdb int (packet link) ;
         IF   word = permanent packet THEN true return
         ELIF end of permanents       THEN false return
         FI ;
     ENDREP .

true return :
     found := TRUE ;
     LEAVE next packet .

false return :
     found := FALSE ;
     LEAVE next packet .

end of permanents :
     word = permanent end OR packet link > end of permanent table 
ENDPROC next packet ;

PROC prep bulletin :
     forget (bulletin ds) ;
     bulletin ds := nilspace ;
     bulletin file := sequential file (output, bulletin ds) ;
     line number := 0 ;
     buffer := ""
ENDPROC prep bulletin ;

PROC show bulletin file :
     IF within editor THEN ueberschrift neu FI ;
     DATASPACE VAR local ds :: bulletin ds ;
     FILE VAR local file :: sequential file (modify, local ds) ;
     show (local file) ;
     forget (local ds)
ENDPROC show bulletin file ;

PROC write bulletin line (TEXT CONST line) :
     IF LENGTH buffer + LENGTH line > 75 THEN writeline FI ;
     buffer CAT line
ENDPROC write bulletin line ;

PROC writeline  :
     write (bulletin file, buffer) ;
     line (bulletin file) ;
     line number INCR 1 ;
     cout (line number) ;
     buffer := indentation * " "
ENDPROC writeline ;

PROC writeline (INT CONST times) :
     IF LENGTH compress(buffer) <> 0 THEN index := times - 1 ;
                                          writeline
                                     ELSE index := times
     FI ;
     line (bulletin file, index) ;
     line number INCR index;
     indentation := 0 ;
     cout (line number)
ENDPROC writeline ;
 
PROC bulletin (TEXT CONST packet name) :
     prep bulletin ;
     scan (packet name) ;
     next symbol (pattern) ;
     to packet (pattern) ;
     IF found THEN list packet ;
                   show bulletin file
              ELSE error stop (packet name + " ist kein Paketname")
     FI . 
 
ENDPROC bulletin ;
 
PROC list packet :
     begin of packet := packet link + word length ;
     write packet name ; 
     find end of packet ;
     run through nametab and list all packet objects .
 
find end of packet :
     last packet entry := begin of packet ;
     REP
         last packet entry INCR wordlength ;
         word := cdb int (last packet entry) ;
     UNTIL end of packet entries PER .

end of packet entries :
     word = permanent packet OR word = permanent end .

run through nametab and list all packet objects :
     hashtable pointer := begin of hashtable ;
     REP
         nt link := hashtable pointer ;
         list objects of current packet in this chain ;
         next hash entry
     UNTIL end of hashtable reached ENDREP .

list objects of current packet in this chain :
     WHILE yet another nt entry REP 
         permanent pointer := cdb int (nt link + wordlength) ;
         put objects of this name
     PER .

put objects of this name :
    IF there is an entry THEN into bulletin FI .

there is an entry :
    NOT packet entry AND
    there is at least one object of this name in the current packet .

there is at least one object of this name in the current packet :
     REP
        IF permanent pointer >= begin of packet AND
           permanent pointer < last packet entry
           THEN LEAVE there is at least one object of this name
                      in the current packet WITH TRUE FI ;
        next procedure
     UNTIL permanent pointer = 0 PER ;
     FALSE .

into bulletin :
     object name := cdb text (nt link + two word length) ;
     object names into bulletin (BOOL PROC within packet)
ENDPROC list packet ;

BOOL PROC within packet :
     permanent pointer >= begin of packet AND 
     permanent pointer < last packet entry
ENDPROC within packet ;

PROC object names into bulletin (BOOL PROC link ok) :
     scan (object name) ;
     next symbol (dummy name, mode) ;
     IF type definition THEN put type definition
                        ELSE put object definitions
     FI .

type definition :
     mode = bold AND no params .

no params :
     cdb int (permanent pointer + word length) >= permanent type .

put type definition :
     put obj name (object name) ;
     write bulletin line ("TYPE ") ;
     writeline (1) .

put object definitions :
     WHILE link ok REP
         put specifications (object name) ;
         next procedure
     ENDREP 
ENDPROC object names into bulletin ;
 
PROC bulletin :
     prep bulletin ;
     packet link := first permanent entry ;
     REP
         list packet ;
         write line (4) ;
         next packet
     UNTIL NOT found PER ;
     show bulletin file
ENDPROC bulletin ;

PROC put obj name (TEXT CONST name) :
     buffer := "      " ;
     bulletin name := point line ;
     change (bulletin name, 1, end of line or name, name) ;
     buffer CAT bulletin name ;
     indentation := LENGTH buffer + 1 .

end of line or name :
     min (LENGTH name, LENGTH bulletin name)
ENDPROC put obj name ;

PROC packets :
     prep bulletin ;
     packet link := first permanent entry ;
     REP
         object name := packet name ;
         put obj name (object name) ;
         write line ;
         next packet 
     UNTIL NOT found PER ;
     show bulletin file
ENDPROC packets ;
 
#page#
(**************************************************************************) 
(*                                                                        *) 
(*                 11. ELAN Run-Interface                     04.08.1986  *) 
(*                                                                        *) 
(*   Uebersetzen von ELAN-Programmen                                      *) 
(*   Bereitstellen der Ausgabeprozeduren fuer den ELAN-Compiler           *) 
(*                                                                        *) 
(**************************************************************************) 
 
 
 
BOOL VAR list option     := FALSE ,
         check option    :=  TRUE ,
         warning option  := FALSE , 
         listing enabled := FALSE ;

FILE VAR listing file ;

TEXT VAR listing file name := "" ;
 
 
PROC run (TEXT CONST file name) : 
  enable stop ;
  IF NOT exists (file name)
    THEN errorstop ("""" + file name + """ gibt es nicht")
  FI ;
  last param (file name) ;
  run elan (file name, no ins)
END PROC run;
 
PROC run :
  run (last param)
ENDPROC run ;
 
PROC run again :
  IF run again mod nr <> 0
    THEN elan (run again mode, bulletin file, "", run again mod nr, 
               no ins, no lst, check option, no sermon)
    ELSE errorstop ("'run again' nicht moeglich")
  FI
ENDPROC run again ;
 
PROC insert (TEXT CONST file name) : 
  enable stop ;
  IF NOT exists (file name)
    THEN errorstop ("""" + file name + """ gibt es nicht")
  FI ;
  last param (file name) ;
  run elan (file name, ins)
ENDPROC insert ;
 
PROC insert :
  insert (last param)
ENDPROC insert ;
 
PROC run elan (TEXT CONST file name, BOOL CONST insert option) :
  FILE VAR source := sequential file (modify, file name) ;
  IF listing enabled
    THEN open listing file
  FI ;

  disable stop ;
  no do again ;
  elan (compile file mode, source, "" , run again mod nr,
        insert option, list option, check option, sermon) ;
 
  IF anything noted AND command dialogue
    THEN ignore halt during compiling ;
         note edit (source) ;
         last param (file name) ; 
         errorstop ("")
  FI .

ignore halt during compiling :
  IF is error
    THEN put error ;
         clear error ;
         pause (5)
  FI .

open listing file :
  listing file := sequential file (output, listing file name) ;
  max line length (listing file, 130)

ENDPROC run elan ;
(*
PROC out text (TEXT CONST text, INT CONST out type) :
  INTERNAL 257 ; 
  IF online
    THEN out (text)
  FI ;
  IF out type = error message OR (warning option AND out type = warning message) 
    THEN note (text) ; 
  FI ;
  IF listing enabled
    THEN write (listing file, text)
  FI
ENDPROC out text ;

PROC out line (INT CONST out type) :
  INTERNAL 258 ; 
  IF online
    THEN out (""13""10"")
  FI ;
  IF out type = error message
       OR (warning option AND out type = warning message)
    THEN note line
  ELIF listing enabled
    THEN line (listing file)
  FI
ENDPROC out line ;
*)
PROC prot (TEXT CONST file name) :
  list option := TRUE ;
  listing file name := file name ;
  listing enabled := TRUE
ENDPROC prot ;
 
PROC prot off :
  list option := FALSE ;
  listing enabled := FALSE
ENDPROC prot off ;

BOOL PROC prot :
  list option
ENDPROC prot ;
 
PROC check on :
  check option := TRUE
ENDPROC check on ;
 
PROC check off :
  check option := FALSE
ENDPROC check off ;
 
BOOL PROC check :
  check option
ENDPROC check ;

PROC warnings on :                    
  warning option := TRUE    
ENDPROC warnings on ;    
 
PROC warnings off : 
  warning option := FALSE 
ENDPROC warnings off ; 
 
BOOL PROC warnings : 
  warning option 
ENDPROC warnings ; 

ENDPACKET eumel coder ;  

PACKET dint2 DEFINES dint type :
 
INT VAR dummy ;
DTYPE VAR d ;
identify ("DINT", dummy, dummy, d) ; 
 
DTYPE CONST dint type := d

ENDPACKET dint2 ;