system/std.graphik/1.8.7/src/Beispiel.Sinus

Raw file
Back to index

initialisiere picfile;
zeichne überschrift;
zeichne achsen;
zeichne sinuskurve;
wähle darstellung;
plot (p)  .

initialisiere picfile:
  PICFILE VAR p :: picture file ("SINUS")  .

zeichne überschrift:
  PICTURE VAR überschrift :: nilpicture;
  move (überschrift, -pi/2.0, 1.0);
  draw (überschrift, "sinus (x)  [-pi, +pi]", 0.0, 1.0, 0.6);
  put picture (p, überschrift)  .

zeichne achsen:
  PICTURE VAR achsen :: nilpicture;
  zeichne x achse;
  zeichne y achse;
  put picture (p, achsen)  .

zeichne x achse:
  move (achsen, -pi, 0.0);
  draw (achsen,  pi, 0.0)  .

zeichne y achse:
  move (achsen, 0.0, -1.0);
  draw (achsen, 0.0, +1.0)  .

zeichne sinuskurve:
  PICTURE VAR sinus :: nilpicture;
  REAL VAR x :: -pi;

  move (sinus, x, sin (x));
  REP x INCR 0.1;
      draw (sinus, x, sin (x))
  UNTIL x >= pi PER;

  put picture (p, sinus)  .

wähle darstellung:
  window (p, -pi, pi, -1.0, 1.3);
  viewport (p, 0.0, 0.0, 0.0, 0.0)  .