(*****************************) 
                                             (*                           *) 
                                             (*         ls-MP BAP         *) 
                                             (*     GENERATORPROGRAMM     *) 
                                             (*                           *) 
                                             (* (c) 1987  (01.09.87)      *) 
                                             (*     by Eva Latta          *) 
                                             (*        Bielefeld          *) 
                                             (*****************************) 
LET mm taskname   = "ls-MENUKARTEN", 
    eigener name  = "ls-MP BAP/gen", 
    datei1        = "ls-MP BAP 1", 
    datei2        = "ls-MP BAP 2", 
    menukarte     = "ls-MENUKARTE:MP-BAP"; 
 
PROC stelle existenz des mm sicher: 
  cursor (1, 5); out (""4""); 
  IF NOT exists (task (mm taskname)) 
     THEN errorstop ("Unbedingt erst den 'MENUKARTEN MANAGER' generieren!"); 
  FI 
END PROC stelle existenz des mm sicher; 
 
PROC vom archiv (TEXT CONST datei): 
  cursor (1,5); out (""4""); 
  out ("  """); out (datei); putline (""" wird geholt.");
  fetch (datei, archive)
END PROC vom archiv;
PROC hole (TEXT CONST datei):
  IF NOT exists (datei) THEN vom archiv (datei) FI
END PROC hole;
PROC in (TEXT CONST datei):
  hole (datei);
  cursor (1, 5); out (""4"");
  out ("  """); out (datei); out (""" wird übersetzt: ");
  insert (datei);
  forget (datei, quiet);
END PROC in;
PROC schicke (TEXT CONST datei):
  cursor (1, 5); out (""4"");
  out ("  """); out(datei);
  out (""" wird zum MENUKARTEN-MANAGER geschickt!");

  command dialogue (FALSE);
  save (datei, task (mm taskname));
  command dialogue (TRUE);
  forget (datei, quiet)
END PROC schicke;
INT VAR size, used;
BOOL VAR einzeln;
storage (size, used);
einzeln := size - used < 500;
forget (eigener name, quiet);
wirf kopfzeile aus;
stelle existenz des mm sicher;
hole die dateien;
insertiere die dateien;
mache global manager aus der task.
wirf kopfzeile aus:
  page;
  putline ("                  "15"ls-MP BAP  -  Automatische Generierung "14"").

hole die dateien:
  IF     NOT exists (datei 1)
     COR NOT exists (datei 2)
     COR NOT exists (menukarte)
     THEN hole dateien vom archiv; LEAVE hole die dateien
  FI.
hole dateien vom archiv:
  cursor (1,3); out (""4"");
  IF yes ("Ist das Archiv angemeldet und die Diskette eingelegt")
     THEN lese ein
     ELSE line (2);
          errorstop ("Ohne die Diskette kann ich das System nicht generieren!")
  FI.
lese ein:
  cursor (1, 3); out (""4"");
  out ("                   "15"Bitte die Diskette eingelegt lassen! "14"");

  IF NOT einzeln
     THEN  hole (datei 1);
           hole (datei 2);
           hole (menukarte);
           cursor (1, 3); out(""4"");
           out ("                  "15"Die Diskette wird nicht mehr benötigt! "14"");
           release (archive)
  FI.
insertiere die dateien:
  check off;
  cursor (1, 3); out(""4"");
  out ("                  "15"Die Diskette wird nicht mehr benötigt! "14"");
  in (datei 1);
  in (datei 2);
  schicke (menukarte);
  IF einzeln THEN release (archive) FI;

  check on.
mache global manager aus der task:
  global manager.