summaryrefslogtreecommitdiff
path: root/devel/misc/unknown/src/COPYDS.ELA
blob: c0bd83c530c7d726dafd9c302b597fd8f828980a (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
LET systemanker = 2 ,      (* Wird bei 'blockin' durch 2 geteilt *) 
    channel field = 4 ,
    hg channel  = 0 ; 
 
ROW 256 INT VAR block ;
INT VAR return ; 
 
PROC pcb (TASK CONST id, INT CONST field, value) : 
 EXTERNAL 105 
ENDPROC pcb ; 
 
PROC copy ds (INT CONST task nr, ds nr, TEXT CONST destination) : 
 DATASPACE VAR ds ; 
 ROW 8 INT VAR dr eintrag ;
 INT VAR old channel := channel, link, i, seite ; 
 
 system channel ; 
 zugriff ueber drdr ; 
 IF ist nilspace 
    THEN ds := nilspace 
 ELIF ist kleindatenraum 
    THEN lese kleindatenraum 
 ELSE lese grossdatenraum 
 FI ; 
 user channel ; 
 forget (destination, quiet) ; 
 copy (ds, destination) ; 
 forget (ds) . 
 
user channel : 
 disablestop ;
 continue (old channel) ; 
 IF iserror 
    THEN forget (ds) ; 
 FI ; 
 enablestop . 
 
system channel : 
 break (quiet) ;                           (* Offiziell abmelden *)
 pcb (myself, channel field, hg channel) . (* Inoffiziell anmelden *)
 
zugriff ueber drdr : 
 systemanker lesen ; 
 drdr taskwurzel lesen ; 
 drdr dataspacewurzel lesen . 
 
erste seite im dreintrag : 
 link := 8 * (dsnr MOD 32) + 1 ; 
 FOR i FROM link UPTO link + 7 REP 
  IF block (i) <> -1 
     THEN LEAVE erste seite im dreintrag WITH i 
  FI 
 PER ; 
 user channel ; 
 errorstop ("Der Datenraum existiert nicht (DR-Eintrag = 8 mal FFFF)") ; 0 . 
 
ist nilspace : 
 block (erste seite im dreintrag) = -255 . 
 
ist kleindatenraum : 
 block (link) > -255 AND block (link) < 0 . 
 
lese kleindatenraum : 
 ds := nilspace ;
 IF seite eins existiert 
    THEN blockin (ds, 1, block (link + 1)) ; 
         IF return <> 0 
            THEN user channel ; 
                 putline ("Warnung: Seite 1 des Datenraums nicht lesbar: " + 
                            text (return)) ; 
                 system channel 
         FI 
 FI ; 
 IF seite zwei existiert 
    THEN blockin (ds, 2, block (link + 2)) ; 
         IF return <> 0 
            THEN user channel ; 
                 putline ("Warnung: Seite 2 des Datenraums nicht lesbar: " + 
                            text (return)) ; 
                 system channel 
         FI 
 FI ; 
 IF mehr als zwei seiten 
    THEN FOR i FROM 0 UPTO 4 REP
          IF hoehere seite existiert 
             THEN blockin (ds, i + basisseite, block (link + i + 3)) ; 
                  IF return <> 0 
                     THEN user channel ; 
                          putline ("Warnung: Seite " + text (i + basisseite)
                                   + " des Datenraums nicht lesbar: " 
                                   + text (return)) ; 
                          system channel 
                  FI 
          FI 
         PER
 FI . 
 
seite eins existiert : 
 exists (block (link + 1)) . 
 
seite zwei existiert : 
 exists (block (link + 2)) . 
 
mehr als zwei seiten : 
 exists (block (link)) . 
 
hoehere seite existiert : 
 exists (block (link + i + 3)) . 
 
basisseite : 
 block (link) AND 255 . 
 
lese grossdatenraum : 
 ds := nilspace ; 
 dreintrag kopieren ; 
 seite := 0 ; 
 FOR i FROM 1 UPTO 8 REP 
  IF seitenblocktabelle existiert 
     THEN seitenblocktabelle lesen ; 
          seiten kopieren wenn sie in der seitenblocktabelle vorhanden sind 
     ELSE seite INCR 256 
  FI 
 PER . 
 
seitenblocktabelle lesen : 
 blockin (dr eintrag (i)) ; 
 IF return <> 0 
    THEN user channel ; 
         putline ("Warnung: Seitenblocktabelle " + text (i-1) + 
                  " des Datenraums nicht lesbar: " + text (return)) ; 
         putline ("Damit fehlen die Seiten " + text (max (1, seite)) +
                  " bis " + text (seite + 255)) ; 
         system channel 
 FI . 
 
seiten kopieren wenn sie in der seitenblocktabelle vorhanden sind : 
 FOR link FROM 1 UPTO 256 REP 
  IF seite vorhanden 
     THEN blockin (ds, seite, block (link)) ; 
          IF return <> 0 
             THEN user channel ; 
                  putline ("Warnung: Seite " + text (seite) + 
                           " des Datenraums nicht lesbar: " + text (return)) ; 
                  system channel 
          FI ;
          user channel ; 
          cout (seite) ; 
          system channel 
  FI ; 
  seite INCR 1 
 PER . 
 
seite vorhanden : 
 exists (block (link)) . 
 
seitenblocktabelle existiert : 
 exists (dreintrag (i)) . 
 
dreintrag kopieren : 
 FOR i FROM 0 UPTO 7 REP 
  dreintrag (i + 1) := block (link + i) 
 PER .
 
systemanker lesen : 
 blockin (systemanker) ;
 IF return <> 0 
    THEN user channel ; 
         errorstop ("Systemanker nicht lesbar: " + text (return))
 FI .
 
drdr taskwurzel lesen : 
 link := block (tasknr DIV 32 + 1) ; 
 IF link = -1 
    THEN user channel ; 
         errorstop ("Die Task existiert nicht") 
 FI ; 
 blockin (link) ; 
 IF return <> 0 
    THEN user channel ; 
         errorstop ("Taskwurzel des DRDR nicht lesbar: " + text (return))
 FI . 
 
drdr dataspacewurzel lesen : 
 link := block (8 * (tasknr MOD 32) + dsnr DIV 32 + 1) ; 
 IF NOT exists (link)
    THEN user channel ; 
         errorstop ("Der Datenraum (und weitere 31) existiert nicht") 
 FI ; 
 blockin (link) ; 
 IF return <> 0 
    THEN user channel ; 
         errorstop ("Dataspacewurzel des DRDR nicht lesbar: " +
                    text (return)) 
 FI . 
 
ENDPROC copy ds ; 
 
BOOL PROC exists (INT CONST blocknr) :
 blocknr <> -1 AND blocknr <> -255
ENDPROC exists ; 
 
PROC blockin (INT CONST blocknr) : 
 blockin (block, 0, blocknr DIV 2, return) ; (* ggf COPBIT ausblenden *) 
ENDPROC blockin ; 
 
PROC blockin (DATASPACE VAR ds, INT CONST page, blocknr) : 
 blockin (ds, page, 0, blocknr DIV 2, return) (* ggf COPBIT ausblenden *)
ENDPROC blockin ; 
 
PROC dump (TEXT CONST datei) : 
 edit dump (datei, FALSE) 
ENDPROC dump ; 
 
PROC edit dump (TEXT CONST datei, BOOL CONST write access) : 
 BOUND STRUCT (ROW 252 INT page1, ROW 2047 ROW 256 INT blocks) VAR b ; 
 b := old (datei) ; 
 INT VAR blocknr :=  1, i ;
 TEXT VAR esc char, t ; 
 BOOL VAR clear := TRUE , modified ; 
 ROW 256 INT VAR page 1 ;
 page 1 (1) := 0 ; 
 page 1 (2) := 0 ; 
 page 1 (3) := type (old (datei)) ; 
 page 1 (4) := -1 ;
 page ; 
 put ("Info mit 'ESC ?'") ; 
 dump cursor (4, 3) ;
 REP 
  out (""1""5"Datei: """) ; out (datei) ; put ("""") ; 
  put (", Page:") ; put (text (blocknr, 5)) ; 
  put (", Dspages:") ; put (text (dspages (old (datei)), 5)) ; 
  put (", Type:") ; put (type (old (datei))) ; 
  IF blocknr = 1 
     THEN FOR i FROM 1 UPTO 252 REP 
           page1 (i + 4) := b.page1 (i) 
          PER ; 
          edit dump (page 1, 1, 256, clear, write access, modified, esc char); 
          IF modified 
             THEN FOR i FROM 1 UPTO 252 REP 
                   b.page1 (i) := page 1 (i + 4) 
                  PER ; 
                  type (old (datei), page 1 (3))
          FI 
     ELSE edit dump (b.blocks (blocknr), 1, 256, clear, write access, modified, esc char) 
  FI ;
  clear := TRUE ;
  IF esc char = ""1""10"" 
     THEN blocknr INCR 1 
  ELIF esc char = ""1""3"" 
     THEN IF blocknr > 1 
             THEN blocknr DECR 1 
             ELSE clear := FALSE ;
                  out (""1""15"E r s t e   S e i t e "14""5"") 
          FI 
  ELIF esc char = ""27"q" 
     THEN LEAVE edit dump 
  ELIF esc char = ""27"?" 
     THEN clear := FALSE ; 
          putline (""1"ESC:?,p,q,w,F,0; HOP:HOP,LEFT,UP,DOWN,RIGHT; DEL,INS,LEFT,UP,RIGHT") ; 
  ELIF esc char = ""27"p" 
     THEN REP 
           put(""1""5"Neue Pagenr:") ; 
           t := text (blocknr) ; 
           editget (t) ; 
           blocknr := int (t) 
          UNTIL blocknr >= 0 AND blocknr < 2048 PER 
  ELSE clear := FALSE 
  FI ; 
 PER 
ENDPROC edit dump ; 
 
INT VAR task index, ds nr ; 
TEXT VAR task id ; 
page ; 
put ("""Taskname"" oder Taskindex:") ; 
getline (task id) ; 
IF pos (task id, """") > 0 
   THEN scan (task id) ; 
        nextsymbol (task id) ; 
        task index := index (task (task id))
   ELSE task index := int (task id) 
FI ;
put ("Dataspacenummer in der Task:") ; 
get (ds nr) ; 
IF ds nr < 4 
   THEN errorstop ("Es gibt nur DATASPACE-Nummern >= 4") 
FI ; 
IF yes ("Soll vorher ein Fixpoint gesetzt werden") 
   THEN fixpoint 
FI ; 
forget ("new ds", quiet) ; 
copy ds (task index, ds nr, "new ds") ; 
putline ("Der kopierte Datenraum steht in der Datei ""new ds""") ; 
dump ("new ds")