1 files changed, 64 insertions, 0 deletions
diff --git a/lang/dynamo/1.8.7/src/dyn.wasseröko b/lang/dynamo/1.8.7/src/dyn.wasseröko
new file mode 100644
index 0000000..fe05881
--- /dev/null
+++ b/lang/dynamo/1.8.7/src/dyn.wasseröko
@@ -0,0 +1,64 @@
+n t=15
+note***   wasserökosystem nach abel und reich
+note***   in: microextra 4/83 seite 34 ff
+note************************************************************************
+note*     hilfsgleichung fuer temperatur t
+note*     die zeit time in wochen
+
+a t.k=15+4*sin((time.k-10)*2*pi/52)    temperatur t; time in wochen
+c pi=3.1415
+note      gleichung fuer phytoplankton p
+
+l p.k=p.j+dt*(p.j*(p1*n.j*t.j-p2*z.j)(100-p.j)/100)  phytoplankton p
+note      gleichung fuer zooplankton  z
+
+l z.k=z.j+dt*(z.j*(p3*t.j*p.j+p4*n.j-(p5*f.j+p6*b.j)-1/p.j)(30-z.j)/30)
+note      gleichung fuer fische f
+l f.k=f.j+dt*(f.j*(p7*z.j-p8*b.j-p9/(z.j+p.j))(10-f.j)/10)
+
+note      gleichung fuer raubfisch barsch b
+
+l b.k=b.j+dt*(b.j*(p10*f.j+p11*z.j-1/(p12*f.j))(0.1-b.j)/0.1)
+
+note **** gleichung fuer naehrstoffmenge n
+
+l n.k=n.j+dt*(p13-n.j*(p14*p.j-p15*z.j))
+note **** anfangswerte ****************************************************
+n    p=p0
+n    z=z0
+n    f=f0
+n    b=b0 
+n    n=n0 
+c    p0=10
+c    z0=3
+c    f0=1
+c    b0=0.01
+c    n0=30          in kg/volumeneinheit bzw. Stück/volumeneinhe�[
+note ***** konstanten ********************************************************
+c    p1=0.006
+c    p2=1
+c    p3=0.006
+c    p4=0.03
+c    p5=1
+c    p6=100
+c    p7=0.33
+c    p8=100
+c    p9=1E-4
+c    p10=1
+c    p11=1
+c    p12=0.25
+c    p13=10
+c    p14=0.1
+c    p15=0.2
+note **** simulationskonstanten *********************************************
+c    dt=0.5
+c    length=60
+c    pltper=1
+note***** outputvariablen****************************************************
+a    lp.k=ln(p.k/p0)
+a    lz.k=ln(z.k/z0)
+a    lf.k=ln(f.k/f0)
+a    lb.k=ln(b.k/b0)
+a    logn.k=ln(n.k/n0)
+plot lp=p,lz=z,lf=f,lb=b,logn=n(-4,4)
+